
READY.

1 REM
2 REM  PLANET.OF.THE.ROBOTS
3 REM  BY DANIEL TOBIAS   11/81
4 REM  AN ADVENTURE-STYLE GAME
5 REM
6 REM  MODEFIKATION AUF CBM 64                 GRAFISCHE VERBESSERUNGEN
7 REM  DEUTSCHE UEBERSETZUNG                           UND
8 REM  VERTRIEB IN DEUTSCHLAND
9 REM                                           **********************
10 REM   THORANIA SOFTWARE                       SCHULENBURGALLEE 140
11 REM   3180 WOLFSBURG 1                       **********************
12 REM                                             5.5. - 17.5.1983
13 REM     ----------------             14 REM
15 PRINT"":NA$="ROBOT-":VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11
16 DIMLV%(100,8),LD$(100,1),R%(100),ID$(50),IL%(50),PR(50),IW(50),L%(100)
17 DIMWD$(150),W%(150,1),FW%(1)
18 PRINTCHR$(151):POKE53248+32,12:POKE53248+33,12
20 GOSUB18000:GOSUB19000
60 PRINT"":PRINT
100 REM  START
108 XX=1
110 IFXX=1THENGOSUB1000
120 GOSUB500
125 XX=XX+1:IFXX>5THENXX=1
130 IFFW%(0)=0THENPRINT"WAS ?":GOTO110
140 ONFW%(0)GOSUB2000,3000,4000,5000,5500,6000,7000,8000,9000,9500
142 IFFW%(0)>10THENONFW%(0)-10GOSUB13000,13500,14500,15000,15500,16000,16500,10000
145 IFFW%(0)=99THENPRINT"ENDE NACH"T"BEWEGUNGEN.":GOTO40000
150 T=T+1:GOTO110
500 REM  EINGABE HANDLUNG
502 POKE649,1:POKE631,0
505 I$="":FW%(0)=0:FW%(1)=0:PRINT:INPUT"-->";I$
515 IFI$=""THENPRINT"":GOTO505
520 WD$="":A=1
530 IFMID$(I$,A,1)=" "THEN600
540 WD$=WD$+MID$(I$,A,1)
550 A=A+1:IFA<=LEN(I$)THEN530
600 REM  WORT GEFUNDEN
610 FORB=1TONW:IFWD$(B)=WD$THENGOSUB650
620 NEXTB:WD$="":A=A+1
630 IFA>LEN(I$)THENRETURN
640 GOTO530
650 FORC=0TO1
660 IFW%(B,C)>=0THENFW%(C)=W%(B,C)
670 NEXTC:RETURN
1000 REM PRINT BESCHREIBUNG
1002 IFLD$(L,0)="S"THENGOSUB12000
1010 PRINT:PRINTLD$(L,L%(L))
1011 IFL=28ANDJ=0THENPRINT"ES GIBT EINE TUER MIT GITTERSTAEBEN."
1012 IFL=28ANDJ<>0THENPRINT"DIE STAEBE SIND ABGEBROCHEN UND GEBEN   DEN WEG";
1013 IFL=28ANDJ<>0THENPRINT"NACH DRAUSSEN FREI."
1014 PRINT:L%(L)=1:POKEVC+34,7
1015 L%(L)=1
1020 PRINT"OFFENE WEGE: ":FORA=1TO8:IFLV%(L,A)<>0THENPRINTDN$(A);
1025 NEXTA:PRINT
1040 PRINT"SICHTBARE GEGENSTAENDE:":X=0:FORA=1TONI
1060 IFIL%(A)=LTHENPRINT" "ID$(A);:X=1:IFPR(A)>0ANDR%(L)=1THEN1062
1061 GOTO1065
1062 PRINT" (PREIS: $"PR(A)")";
1065 IFIL%(A)=LTHENPRINT
1070 NEXTA
1080 IFX=0THENPRINT"ES SIND KEINE DA."
1085 IFR%(L)<>0THENPRINT
1090 IFR%(L)=1THENPRINT"EIN ANGESTELLTER ROBOTER IST DA."
1100 IFR%(L)>20ANDR%(L)<29THENPRINT"EIN WACH-ROBOTER IST DA."
1110 IFR%(L)=3THENPRINT"EIN WUETENDER UND RASENDER ROBOTER IST  DA."
1111 IFR%(L)=3THENPRINT" !"
1120 IFT-E>=100THENPRINT:PRINT"DU WIRST LANGSAM !"
1490 RETURN
2000 REM  BEWEGUNGEN
2005 IFFW%(1)<101ORFW%(1)>108THENPRINT"GEHE WOHIN?":RETURN
2010 X=LV%(L,FW%(1)-100)
2020 IFX<0ORX>NLTHENPRINT"DALANG GEHT'S IM MOMENT NICHT.":RETURN
2025 IFL=28ANDI$="BRICH AUS"THEN15000
2030 IFX=0THENPRINT"DU KANNST DA NICHT LANG GEHEN.":RETURN
2035 IFR%(L)=3THENPRINT"ROBOTER: VERSUCHST WOHL ZU ENTWISCHEN,  WAS?   ";
2036 IFR%(L)=3THENPRINT"DAS WIRD NICHT KLAPPEN!":FORR=1TO1000:NEXT
2037 IFR%(L)=3THENPRINT:PRINT"             ZAFLAPP !":FORR=1TO1000:NEXT:PRINT
2038 IFR%(L)=3THENPRINT"DU BIST TOD!":PRINT:PRINT"-SCHLUSS NACH"T"VERSUCHEN.-"
2039 IFR%(L)=3THENGOTO40000
2040 IFX=6ANDIL%(7)<>0THENPRINT"ROBOTER: TUT MIR LEID, ABER NACH DEN    VORSCHRIFTE";
2041 IFX=6ANDIL%(7)<>0THENPRINT"N MUESSEN SIE EINE KRAWATTE  TRAGEN.":RETURN
2042 IFL=6ANDR<>0THENPRINT"ROBOTER: TUT MIR LEID, ABER SIE SIND    NICHT VER";
2043 IFL=6ANDR<>0THENPRINT"TRAUENSWUERDIG. SIE DUERFEN DA NICHT REIN !":RETURN
2045 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT"ROBOTER: I.D. KARTE AKZEPTIERT";
2046 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT". SIE     KOENNEN PASSIEREN. ";
2047 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT"GUTEN TAG, MR. SMITH.":GOTO2060
2050 IFR%(L)=20+FW%(1)-100THENPRINT"ROBOTER: TUT MIR LEID,ABER OHNE I.D.KAR-T";
2051 IFR%(L)=20+FW%(1)-100THENPRINT"E DARF ICH SIE DA NICHT REINLASSEN.":RETURN
2060 REM
2065 IFL=39ANDX=39ANDRND(1)<.35THENPL=1-PL:X=35:IFPL=0THENX=40
2070 IFX=17THENPRINT"ROBOTER:KANN ICH IHNEN BEHILFLICH SEIN?"
2071 IFX=17THENGOSUB30000:RETURN
2080 IFLD$(X,0)="S"THENGOSUB12000:RETURN
2090 IFL=36ANDX=37THENINPUT"GEBE KOMBINATION EIN:";A$
2091 IFL=36ANDX=37THENIFVAL(A$)<>CM%THENPRINT"LEIDER FALSCH!":RETURN
2100 IFX=38THEN14000
2200 L=X:XX=1:RETURN
3000 REM  AUFHEBEN
3005 IFFW%(1)=0ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
3006 IFIL%(FW%(1))=0THENPRINT"DU TRAEGST ES BEREITS!":RETURN
3007 IFIL%(FW%(1))<>LTHENPRINT"DAS GIBT'S HIER NICHT.":RETURN
3009 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"ROBOT: SIE KOENNEN ES NICHT NEHMEN, OHN";
3010 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"EDAFUER ZU ZAHLEN. KAUFEN SIE ES, WENN";
3011 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"   SIE ES HABEN WOLLEN.":RETURN
3015 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"ZU SCHWER. DU MUSST ERST";
3016 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"EINMAL ETWAS    FALLEN L";
3017 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"ASSEN.":RETURN
3020 IFIW(FW%(1))>150THENPRINT"ZU SCHWER ZUM HOCHHEBEN FUER DICH.":RETURN
3030 IFIW(FW%(1))<0THENPRINT"ES IST AUS SICHERHEITSGRUENDEN FESTGE-  SCHRAUBT":RETURN
3040 IL%(FW%(1))=0=WT=WT+IW(FW%(1))
3045 PRINT"OK."
3050 IFFW%(1)=10THENM=ABS(M)
3060 RETURN
4000 REM  FALLENLASSEN
4010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"DU TRAEGST ES ABER NICHT!":RETURN
4020 IFIL%(FW%(1))<>0THENPRINT"DU TRAEGST ES ABER NICHT!":RETURN
4030 IL%(FW%(1))=L:WT=WT-IW(FW%(1))
4040 PRINT"OK."
4042 IFL=39THENPRINT"ES RUTSCHT IN EINE SPALTE DER RUINEN UND IST WEG."
4043 IFL=39THENIL%(FW%(1))=-1
4045 IFFW%(1)=10THENM=-ABS(M)
4050 RETURN
5000 REM  UMSCHAUEN
5010 XX=1:L%(L)=0:RETURN
5500 REM  INVENTAR
5510 X=0:PRINT"DU SCHLEPPST MIT DIR 'RUM:":FORA=1TONI
5525 IFA=10THEN5540
5530 IFIL%(A)=0THENPRINT" "ID$(A):X=1
5540 NEXTA
5545 IFM>0THENPRINT" $"M" IN BAR.":X=1
5550 IFX=0THENPRINT"NICHTS."
5560 RETURN
6000 REM  SAVE SPIEL
6010 INPUT"SPIEL #";A
6016 INPUT"DISK ODER KASSETTE (D/K) ";A$
6017 IFA$<>"D"ANDA$<>"K"THEN6016
6018 IFA$="D"THENAA=8:GOTO6020
6019 AA=1
6020 OPEN1,AA,1,NA$+STR$(A)
6030 PRINT#1,L:FORB=1TONI:PRINT#1,IL%(B):NEXTB:PRINT#1,WT:PRINT#1,T
6050 FORB=1TONL:PRINT#1,R%(B):NEXTB:PRINT#1,M:PRINT#1,E
6060 FORB=1TONI:PRINT#1,PR(B):NEXTB
6070 PRINT#1,CM%:PRINT#1,R:PRINT#1,J
6080 PRINT#1,PW:PRINT#1,RM
6090 CLOSE1:RETURN
6500 REM  LOAD SPIEL
6510 INPUT"SPIEL #";A
6515 IFA<0THEN6510
6516 INPUT"DISK ODER KASSETTE (D/K) ";A$
6517 IFA$<>"D"ANDA$<>"K"THEN6516
6518 IFA$="D"THENAA=8:GOTO6520
6519 IFA$="K"THENAA=1:GOTO6520
6520 OPEN1,AA,0,NA$+STR$(A)
6530 INPUT#1,L:FORB=1TONI:INPUT#1,IL%(B):NEXTB:INPUT#1,WT:INPUT#1,T
6550 FORB=1TONL:INPUT#1,R%(B):NEXTB:INPUT#1,M:INPUT#1,E
6560 FORB=1TONI:INPUT#1,PR(B):NEXTB
6570 INPUT#1,CM%:INPUT#1,R:INPUT#1,J
6575 IFJTHENLV%(28,8)=27
6580 INPUT#1,PW:INPUT#1,RM:CLOSE1:RETURN
7000 REM  WIEGEN
7010 IFIL%(2)<>LANDIL%(2)<>0THENPRINT"ES GIBT KEINE WAAGE.":RETURN
7020 IFFW%(1)=2THENPRINT"DU KANNST SIE NICHT AUF SICH SELBER WIEGEN.":RETURN
7030 IFFW%(1)<1ORFW%(1)>NITHENPRINT"DIESEN GEGENSTAND GIBT'S HIER NICHT.":RETURN
7040 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"DIESEN GEGENSTAND GIBT'S HIER ";
7041 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"NICHT.":RETURN
7050 PRINT"ES WIEGT ";IW(FW%(1));"PFUND."
7060 RETURN
8000 REM  LESEN
8005 IFFW%(1)=200THENPRINT"DIE GITTERSTAEBE SEHEN ROSTIG UND"
8006 IFFW%(1)=200THENPRINT"WACKELIG AUS.":RETURN
8010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
8020 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"GIBT'S HIER NICHT.":RETURN
8030 IFFW%(1)=5THENPRINT"DAS SCHILD BEDEUTET: WERFE $2.50 EIN.":RETURN
8050 IFFW%(1)=10THENPRINT"ES SIND VOR ALLEM DOLLAR MUENZEN, ABER  ES GIBT ";
8051 IFFW%(1)=10THENPRINT"AUCH EIN PAAR $2.50 STUECKE.":RETURN
8060 IFFW%(1)=4THENPRINT"ER HAT EIN MODEM MIT ANSCHLUSS AN DIE   BEZIRKSREGIERNG.":RETURN
8070 IFFW%(1)=8THENPRINT"ES IST DAS ABENTEUER VON SUPERROBOT.":GOSUB31000:RETURN
8080 IFFW%(1)=12THENPRINT"ES GEHOERT DEM SICHERHEITSBEAMTEN       BILL SMITH ";
8081 IFFW%(1)=12THENPRINT"UND HAT HOECHSTE VOLLMACHTEN.";:RETURN
8090 IFFW%(1)=14THENPRINT"ES SIND DIE UEBERRESTE DES FLEISCHERMES-SERS.":RETURN
8100 IFFW%(1)=11THEN8200
8110 IFFW%(1)=13THEN8300
8190 PRINT"NICHTS INTERESANTES.":RETURN
8200 REM  COMPUTER
8205 POKEVC+34,5:PRINT"                 :"
8206 PRINT"**        **              "
8210 PRINT:PRINT"SIE KOENNEN MIT JEDEM COMPUTER, DER MIT EINEM MODEM AUSGERUESTET IST";
8211 PRINT", DIE DATEN DER BEZIRKSREGIERUNG ABRUFEN."
8212 PRINT"MAN BRAUCHT NUR FOLGENDES EINZUGEBEN:"
8220 PRINT" >  1-12-1"
8230 PRINT"DANN WAEHLT MAN DIE DATEI DER BEZIRKSRE-GIERUNG AUS.[ ERMEN-ENG.";
8231 PRINT"=(BEZIRKS) -REGIERUNG ]":PRINT" >  "
8240 PRINT"SIE WERDEN NUN VOM COMPUTER NACH DEM    NAMEN DES GEWUENSCHTEN ";
8241 PRINT"FILES GEFRAGT.":PRINT"EIN FILE ZU DEM SIE ZUGANG HABEN HEISST  >";
8242 PRINT"  ":PRINT"UND BEINHALTET DIE GEGENWAERTIGE BE-    VOELKERUNGSTRUKTUR";
8243 PRINT" DER U.S.A.":PRINT"VIEL SPASS."
8260 RETURN
8300 REM  BRIEF
8305 POKEVC+34,8:PRINT"          ԠϠРӠŠàҠŠ"
8310 PRINT"AN DIE ARBEITER DES PROJEKTES 
8320 PRINT:PRINT"DIE GEGENWAERTIGE  DER TUER  DES RAUMES "RM" STEHT IN DER ";
8321 PRINT"DATEI":PRINT"DER BEZIRKSREGIERUNG AUF DEM FILE MIT   DEM NAMEN ''."
8322 PRINT"DAS PASSWORD DES FILES IST '"PW$(PW)"'."
8330 RETURN
8490 RETURN
8500 REM  PROZESS/GEFAENGNIS
8510 POKEVC+34,4:PRINT"   *  -   *"
8515 PRINT""
8520 PRINT"POLIZEI: SIE SIND VERHAFTET.SIE HABEN   DAS RECHT DIE EINGABE ZU VERW";
8525 PRINT"EIGERN.    ALLES, ALLES WAS SIE EINGEBEN, KANN IM  PROZESS GEGEN SIE V";
8530 PRINT"ERWENDET WERDEN."
8540 PRINT:PRINT"*          *             
8541 PRINT"* *      * *            
8550 PRINT
8560 PRINT:PRINT"RICHTER: IHNEN WIRD VORGEWORFEN EINEN
8580 IFCH=1THENPRINT"ROBOTER ANGEGRIFFEN ZU HABEN.
8590 IFCH<>1THENPRINT"DIEBSTAHL VON ESSENSWAREN GETAETIGT ZU  HABEN.
8600 PRINT"AUF WAS PLEDIEREN SIE?"
8605 PRINT
8610 INPUT"ANGEKLAGTER:";I$
8615 PRINT:IFLEFT$(I$,8)="SCHULDIG"THEN8900
8620 FORR=1TOLEN(I$)
8621 IFMID$(I$,R,1)="S"THENIFMID$(I$,R,8)="SCHULDIG"THEN8623
8622 NEXTR:GOTO8630
8623 IFR-2<0THEN8622:IFMID$(I$,R-2,10)="UNSCHULDIG"THEN8622
8624 IFMID$(I$,R-2,10)="UNSCHULDIG"THEN8622
8625 GOTO8900
8630 PRINT"RICHTER: DER STAATSANWALT WIRD NUN SEINEBEWEISE VORLEGEN."
8635 PRINT
8640 PRINT"*      *";
8645 PRINT
8650 PRINT"STAATSW.: ICH FORDERE DEN ";
8660 IFR%(L)=1THENPRINT"ANGESTELLTEN"
8665 IFR%(L)<>1THENPRINT"WACH-"
8670 PRINT"ROBOTER, SERIENNUMMER #"INT(RND(1)*999999)"AUF,ZU":PRINT"BERICHTEN."
8672 PRINT
8677 IFCH<>1THEN8700
8680 PRINT"ROBOTER: DIESER MENSCH GRIFF MICH MIT   EINE";
8681 IFIL%(9)=0THENPRINT"R STRAHLENWAFFE ";
8685 IFIL%(9)<>0THENPRINT"M FLEISCHERMESSER ";
8687 PRINT"VOR NUR":PRINT""INT(RND(1)*59)"MINUTEN,"RND(1)*59;
8688 PRINT"SEKUNDEN, AN.":PRINT
8695 PRINT"STAATSW.: ICH BEENDE DIE BEWEISAUFNAHME."
8697 GOTO8800
8700 REM  DIEBSTAHL VON ESSENSWAREN
8710 PRINT"ROBOTER: DIESER MENSCH NAHM EINE MAHL-  ZEIT IN DEM RESTAURANT EIN,";
8711 PRINT"  DAS MICH   BESCHAEFTIGT UND BEZAHLTE SEINE RECHNUNGNICHT."
8720 PRINT"STAATSW.: WANN WAR DAS?"
8730 PRINT"ROBOTER: GERADE VOR"INT(RND(1)*59)"MINUTEN,":PRINT""RND(1)*59"SEKUNDEN."
8735 PRINT
8740 PRINT"STAATSW.: HIERMIT SCHLIESE ICH DIE BE-  WEISAUFNAHME."
8745 PRINT
8800 REM  DEINE VERTEIDIGUNG
8801 PRINT"DRUECKE EINE TASTE."
8802 GETI$:IFI$=""THEN8802
8810 PRINT:PRINT"RICHTER: WAS HAT DER ANGEKAGTE NOCH DA- ZU ZU SAGEN?"
8815 PRINT
8820 INPUT"ANGEKLAGTER:";I$:IFI$=CHR$(13)THENPRINT:PRINT"RICHTER:  !":GOTO8820
8822 PRINT
8825 PRINT"RICHTER: DIE GESCHWORENEN WERDEN NUN    UEBER DEN URTEILSSPRUCH BERATEN."
8826 FORA=1TO2000:NEXT
8827 PRINT
8830 PRINT"GESCHWORENER: DAS WORT EINES ROBOTER ISTGLAUBWUERDIGER ALS DAS EINES ";
8831 PRINT"MENSCH-    LICHEN WESENS. DESHALB BEFINDE ICH DEN  ANGEKLAGTEN NACH DER ";
8832 PRINT"ANKLAGE FUER       SCHULDIG.
8840 PRINT
8900 REM  URTEIL
8905 SE=2:PRINT"RICHTER: SIE SIND HIERMIT ZU";
8910 IFCH<>1THEN8920
8911 PRINT"M  AUF  DEM   VERURTEILT."
8912 PRINT:PRINT:PRINT"DU HAST .":PRINT"ENDE NACH"T" VERSUCHEN.":END
8920 PRINT" "SE"JAHREN  ZUCHTHAUS VRURTEILT.":PRINT"GERICHTSDIENER, BITTE!
8921 PRINT"SCHAFFEN SIE DEN GEFANGENEN WEG...      NAECHSTER FALL!"
8930 PRINT:L=28
8940 FORA=1TONI:IFIL%(A)=0THENIL%(A)=29
8942 M=-ABS(M)
8945 NEXTA
8950 XX=1:RETURN
9000 REM  SCHUSS
9010 IFIL%(9)<>0THENPRINT"MIT WAS DENN?":RETURN
9020 IFR%(L)=0THENPRINT"NICHTS ZUM DRAUFSCHIESEN DA.":RETURN
9030 IFR%(L)<>3THENPRINT"DER SCHUTZSCHILD DES ROBOTER HAELT DIE  STRAHLEN ZURUECK."
9031 IFR%(L)<>3THENCH=1:GOTO8500
9040 PRINT"DER DEFEKT, DER DEN ROBOTER ZUR FEHL-   FUNKTION BRACHTE, BEEINTRAECH";
9041 PRINT"TIGTE AUCH SEINEN NORMALEN UNVERWUNDBAREN SCHUTZ-  SCHILD."
9042 PRINT"DEIN SCHUSS HAT DEN ROBOTER ZERSTOERT."
9060 R%(L)=0
9070 RETURN
9500 REM  KAUFEN
9501 IFFW%(1)<1ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
9503 IFIL%(FW%(1))=0THENPRINT"DU SCHLEPPST ES SCHON MIT DIR 'RUN.":RETURN
9505 IFIL%(FW%(1))<>LTHENPRINT"GIBT'S HIER NICHT.":RETURN
9510 IFPR(FW%(1))=0THENPRINT"DA IST KEIN PREISSCHILD DRAUF.":RETURN
9520 P=PR(FW%(1))
9530 IFP>MTHENPRINT"DU HAST NICHT GENUG GELD!":RETURN
9540 M=M-P
9550 PR(FW%(1))=0
9560 GOTO3000
10000 REM  COMPUTER
10002 IFIL%(4)<>LTHENPRINT"NICHTS ZUM EINSCHALTEN DA.":RETURN
10005 PRINT"ROBOTER: WENN SIE FERTIG SIND DANN TIP- PEN SIE 'OFF' EIN, UM IHN AUS";
10006 PRINT"ZUSCHALTEN."
10007 INPUT"DRUECKE NUN RETURN UM DEN COMMODORE     ANZUSCHALTEN.";I$
10010 PRINT"     **** COMMODORE BASIC V.9 ****":PRINT
10020 PRINTTAB(6)2^26"KILO BYTES SYSTEM":PRINT:PRINTTAB(6)2^25"BASIC BYTES FREE"
10030 PRINT:INPUT">";I$
10040 IFI$="OPEN1-12-1"THEN10100
10041 IFI$="O1-12-1"THEN10100
10045 IFI$="OFF"THENXX=1:RETURN
10046 IFI$="?"ORI$="PRINT"THENPRINT"":GOTO10030
10047 IFLEFT$(I$,1)="?"ANDLEN(I$)>2THENPRINTMID$(I$,3,LEN(I$)-3):GOTO10030
10048 IFLEFT$(I$,5)="PRINT"ANDLEN(I$)>6THENPRINTMID$(I$+" ",7,LEN(I$)-7):GOTO10030
10050 I=INT(RND(1)*5)+1:PRINT"?";
10055 ONIGOSUB10060,10065,10070,10075,10080:PRINT"READY.":GOTO10030
10060 PRINT"SYNTAX ERROR":RETURN
10065 PRINT"INPROPER DELIMITER ERROR":RETURN
10070 PRINT"UNBALANCED COORDINATE ERROR":RETURN
10075 PRINT"UNFORMATTED REFERENCE ERROR":RETURN
10080 PRINT"UNINDEXABLE ADRESS ERROR":RETURN
10100 REM  NETWORK DATEI
10110 PRINT:PRINT"SIE SIND NUN IM DATEIEN-MODUS"
10120 PRINT:INPUT"]";I$
10125 IFI$="OFF"THENXX=1:RETURN
10130 IFI$<>"GOVT"THENPRINT"IMPROPPER DATA BANK REFERENCE":GOTO10120
10140 INPUT"FILE NAME: ";I$
10150 IFI$="POP"THENPRINT"GEGENWAERTIGE BEVOELKERUNG DER U.S A.   NACH BERICHTEN ";
10151 IFI$="POP"THENPRINT"DES CITICEN BUREAU       VOM 7/9/2121:"
10152 IFI$="POP"THENPRINT"EXAKT 0 PERSONEN":PRINT"23.241.203 ROBOTER":GOTO10120
10160 IFI$="CHRONOS"THEN10200
10170 PRINT"NO SUCH FILE":GOTO10120
10200 REM  CHRONOS
10210 INPUT"PASSWORD: ";I$
10220 IFI$<>PW$(PW)THENPRINT"IMPROPER PASSWORD":GOTO10120
10230 PRINT"DIE KOMBINATION IST :"CM%
10240 GOTO10120
11000 REM  RESTAURANT
11010 PRINT"ROBOTER: HIER IST DIE KARTE:"
11020 PRINT"    (1) MARSBURGER
11025 PRINT"        $50
11030 PRINT"    (2) 'GRUENER BAUER' (SPEZIALITAET)
11035 PRINT"        $140
11040 PRINT"    (3) KAVIAR UND CHAMPAGNER
11045 PRINT"        $350
11047 PRINT"(DRUECKE RETURN WENN DU NICHT BESTELLEN MOECHTEST.)
11050 PRINT:I$="":INPUT"IHRE BESTELLUNG: ";I$
11060 IFI$=""THENRETURN
11070 IFVAL(I$)<1ORVAL(I$)>3THEN11050
11080 PRINT"ES WIRD AUFGETRAGEN.":FORRR=1TO1000:NEXT
11090 PRINT:PRINT"MMM. ES SCHMECKT GUUUT.":FORRR=1TO1000:NEXT
11100 PRINT:PRINT"ROBOTER: MEIN HERR, IHRE RECHNUNG."
11101 IFM<50THEN11120
11102 IFVAL(I$)=1THENFORRR=1TO1000:NEXT:PRINT"ROBOTER: DANKE, MEIN HERR."
11103 IFVAL(I$)=1THENM=M-50:RETURN
11120 PRINT:PRINT"DU HAST NICHT GENUG GELD!":FORT=1TO1000:NEXT:PRINT
11130 CH=0:GOTO8500
12000 REM  UNTERGRUNDBAHN
12005 L=LV%(L,6)
12010 PRINT"DU BETRITST DIE U-BAHN AN DER":PRINTLD$(L,1)" STATION."
12015 PRINT
12020 IFLV%(L,1)<>0ANDLV%(L,2)<>0THENPRINT"WELCHER ZUG: NACH NORDEN ODER SUEDEN?
12021 IFLV%(L,1)<>0ANDLV%(L,2)<>0THENINPUTI$:I=2:IFLEFT$(I$,1)="N"THENI=1
12030 IFLV%(L,1)=0THENI=2
12040 IFLV%(L,2)=0THENI=1
12050 L=LV%(L,I)
12060 PRINT"NAECHSTE STATION: "LD$(L,1)
12065 IFLV%(L,I)=0THENPRINT"ENDSTATION.":L=LV%(L,8):XX=1:RETURN
12070 PRINT
12080 INPUT"MOECHTEST DU AUSSTEIGEN? ";I$:IFLEFT$(I$,1)="J"THENL=LV%(L,8)
12081 IFLEFT$(I$,1)="J"THENXX=1:RETURN
12090 PRINT:GOTO12050
13000 REM  ROBOTER ANREDEN
13002 IFR%(L)=0THENPRINT"NIEMAND ZUM ANSPRECHEN DA.":RETURN
13003 IFR%(L)<>1THEN13200
13010 IFL=6THEN11000
13020 IFL=34THEN13300
13030 IFL=36THEN13400
13040 IFL=3THENPRINT"ROBOTER: MOECHTEN SIE DEN COMMODORE 640 AUSPROBIEREN?":INPUTI$
13041 IFL=3THENIFLEFT$(I$,1)="J"THEN10000
13045 IFL=3THENRETURN
13050 PRINT"ROBOTER: KANN ICH IHNEN HELFEN?"
13060 INPUTI$
13065 IFI$=""THEN13060
13070 GOSUB520
13080 IFFW%(0)=10THENGOSUB9500
13085 IFFW%(1)=4ANDL=3THEN10000
13090 PRINT"ROBOTER: ICH BIN NICHT PROGRAMMIERT FRA-GEN DIESES TYPS ZU BEANTWORTEN."
13190 RETURN
13200 REM  WACH- UND BESCHEUERTE ROBIS
13210 IFR%(L)=3THENPRINT"DER ROBOTER BRINGT DICH UM, WAEHREND    DU VERSUCHST MIT ";
13211 IFR%(L)=3THENPRINT"IHM ZU KOMMUNIZIEREN.":PRINT:PRINT"STOP NACH"T"BEWEGUNGEN.":END
13220 PRINT"ROBOTER: JA?"
13230 INPUTI$
13240 IFI$<>""THENPRINT"ROBOTER: ERZAEHLEN SIE DAS DEM RICHTER."
13250 RETURN
13300 REM  UNIVERSITAET
13310 PRINT"ROBOTER: WELCHE RAUMNUMMER BENOETIGEN   SIE?":INPUTI$
13320 IFVAL(I$)<>RMTHENPRINT"ROBOTER: TUT MIR LEID, ABER DIESER RAUM IST NICHT OFFEN."
13321 IFVAL(I$)<>RMTHENRETURN
13330 PRINT:PRINT"EINE WAND TUT SICH AUF, UND DU FAEHRST  AUF EINER PLATTFORM ";
13331 PRINT"DURCH VERSCHIEDENE  KORRIDORE.":PRINT"DANN HAELT DAS GEFAEHRT AN."
13340 L=36:XX=1:RETURN
13400 REM  HALLE
13410 PRINT"ROBOTER: WOLLEN SIE IN DIE VORHALLE     ZURUECK?":INPUTI$
13411 IFLEFT$(I$,1)="J"THENL=34:XX=1:RETURN
13420 RETURN
13500 REM  VIDEOSPIEL
13510 PRINT:PRINT"KOSTEN: $2.50"
13520 IFM<2.5THENPRINT"DU KANNST ES NICHT BEZAHLEN.":RETURN
13525 :
13530 M=M-2.5
13540 GOSUB50000
13810 XX=0:GOSUB1000:RETURN
14000 REM  ZEITMASCHINE
14010 PRINT"DU BIST NUN IN DER ZEITMASCHINE!"
14020 PRINT"SETZE DIE KONTROLLEN."
14030 INPUT"JAHR";Y
14040 INPUT"MONAT";I$:INPUT"TAG";I$:INPUT"STUNDE";I$:INPUT"MINUTE";I$
14045 INPUT"SEKUNDE";I$
14050 PRINT"DIE ZEITMASCHINE BRUMMT..."
14060 FORA=1TO1000:NEXTA
14070 PRINT"DU BIST DA!"
14080 IFY>=1970ANDY<2000THENPRINT"ZUM SCHLUSS DOCH NOCH INS 20.JAHRHUNDERTZURUECK";
14081 IFY>=1970ANDY<2000THENPRINT"GEKEHRT.":PRINT"DU HAST GEWONNEN.";
14085 :
14090 IFY>2000THENPRINT"WAS SOLL DEN DAS??":PRINT"WARUM WIEDER IN DIE ZUKUNFT??"
14100 IFY<1970ANDY>=1900THENPRINT"NA, BISSCHEN FRUEH, WAS? DA WIRST DU    NOCH";
14101 IFY<1970ANDY>=1900THENPRINT1970-Y"JAHRE WARTEN MUESSEN, BIS ES ";
14102 IFY<1970ANDY>=1900THENPRINT"   COMMODORE COMPUTER GIBT."
14110 IFY<1900THENPRINT"ANGEKOMMEN IM JAHRE"Y".":PRINT"WARUM IN DIE VERGANGEN";
14111 IFY<1900THENPRINT"HEIT GEFLOGEN?"
14115 IFY<1900ORY>2000THENPRINT"FUER DAS JAHR HABE ICH KEIN ";
14116 IFY<1900ORY>2000THENPRINT"ADVENTURE-  SPIEL GESCHRIEBEN.":PRINT"DU BIST ";
14117 IFY<1900ORY>2000THENPRINT"NUN AUF DICH  ALLEIN GESTELLT,"
14118 IFY<1900ORY>2000THENPRINT"DA DIE ZEITMASCHINE KEINEN TREIBSTOFF"
14119 IFY<1900ORY>2000THENPRINT"MEHR HAT."
14120 PRINT:PRINT"ENDE NACH"T"VERSUCHEN.":GOTO40000
14500 REM  ESSEN
14502 IFFW%(1)=0ANDL=6THEN11000
14510 IFFW%(1)<1ORFW%(1)>NITHENPRINT"WAS ESSEN?":RETURN
14520 IFIL%(FW%(1))<>0THENPRINT"WAS ESSEN?":RETURN
14530 IFIW(FW%(1))>2THENPRINT"MACH DICH NICHT LAECHERLICH.":RETURN
14540 IFFW%(1)=3THENPRINT"MMM. DAS WAR GUT.":E=T:GOTO14565
14542 :
14545 A$=" MAMPF...SCHMURKS...SCHMATZ....":FORI=1TOLEN(A$):PRINTMID$(A$,I,1);
14546 FORR=1TO250:NEXT:NEXT
14550 PRINT"DU HAETTEST NIOCH EIN BISSCHEN SALZ NEH-MEN KOENNEN."
14560 IFT-E>150THENPRINT"NICHT GERADE SEHR NAHRHAFT."
14561 IFT-E>150THENPRINT"ICH BIN NOCH HUNGRIG!"
14565 IL%(FW%(1))=-1
14567 IFFW%(1)=10THENM=0
14570 RETURN
15000 REM  BRICH AUS GEFAENGNIS
15010 IFL<>28THENPRINT"WAS?":RETURN
15020 PRINT"DIE ROSTIGEN, ALTEN STANGEN BRECHEN RAUSUND GEBEN DEN WEG NACH ";
15021 PRINT"DRAUSSEN FREI."
15030 LV%(28,8)=27:J=1
15040 RETURN
15500 REM  ANGRIFF ROBOTER
15510 IFIL%(9)=0THEN9000
15515 IFR%(L)=0THENPRINT"NICHTS ZUN ANGREIFEN DA.":RETURN
15520 IFIL%(1)<>0THENPRINT"DU HAST KEINE CHANGE EINEN KAMPF GEGEN  EINEN ";
15521 IFIL%(1)<>0THENPRINT"HARTEN METALLROBOTER MIT BLOSSEN  HAENDEN ZU GEWINNEN";15522 IFIL%(1)<>0THENRETURN
15530 PRINT"DAS MESSER KNALLT GEGEN DIE HARTE SEITE DES ROBOTERS."
15535 IL%(1)=-1
15537 IL%(14)=L
15538 IFR%(L)=3THENPRINT"DER ROBOTER BRINGT DICH UM."
15539 IFR%(L)=3THENPRINT"AUS NACH"T"VERSUCHEN.":GOTO40000
15540 CH=1:GOTO8500
16000 REM  OPEN
16010 PRINT"ALLE TUEREN OEFFNEN UND SCHLIESSEN AUTO-MATISCH. DAHER IST ES ";
16011 PRINT"NICHT NOETIG SIE  ZU OEFFNEN ODER ZU SCHLIESSEN.
16020 RETURN
16500 REM  HILF
16510 PRINT"":PRINT:POKEVC+34,7
16520 PRINT"EINIGE NUETZLICHE BEFEHLE:":PRINT:PRINT"(ENTAR)"
16530 PRINT" (OBJEKT)":PRINT" (OBJEKT)":PRINT" (OBJEKT) [ETWAS WEGWERFEN]
16540 PRINT" (OBJEKT)":PRINT" [SPRICH ROBOTER AN]"
16541 PRINT"Ơ":PRINT"[ER]Ӡ":PRINT" [UMSCHAUEN]"
16542 PRINT"TEILE IN [ ]  MIT EINTIPPEN."
16550 PRINT:RETURN
17990 RETURN
18000 REM  TITEL
18010 PRINT"";
18030 PRINT"     **** PLANET OF THE ROBOTS ****"
18031 PRINT"                ROBOT WAR
18040 PRINT:PRINT"     VON DANIEL TOBIAS     NOV.1981
18060 PRINT
18070 PRINT:PRINT:PRINT:INPUT"           ANLEITUNG? (J/N) ";I$
18071 IFLEFT$(I$,1)="N"THENPRINT"":PRINT:RETURN
18500 REM  ANLEITUNG
18510 PRINT"":PRINT:POKEVC+34,8
18520 PRINT"DURCH EINEN ZEITSPRUNG WURDEST DU       POETZLICH IN DIE ZUKUNFT BE";
18523 PRINT"FOERDERT.":PRINT
18525 PRINT"EIN KRIEG MIT NEUTRONENBOMBEN UND BAK-  TERIOLOGISCHEN";
18527 PRINT" WAFFEN ";
18530 PRINT"HAT DIE MENSCHEN  AUSGEROTTET.":PRINT:PRINT"ABER DIE COMPUTER UND ROBOTER HA";
18535 PRINT"BEN DAS NICHT GEMERKT UND TUN SO, ALS OB NICHTS GESCHEHEN WAERE."
18585 PRINT:PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18590 PRINT:PRINT:PRINT"UM DIE WELT ZU ERKUNDEN, IN DER DU GE-"
18600 PRINT"LANDET BIST, TIPPE EINFACHE SAETZE EIN"
18605 PRINT"WIE:":PRINT"'Ơ' ODER":PRINT"'Š'."
18620 PRINT:PRINT"WENN EIN ROBOTER IM RAUM IST, KANNST DU"
18625 PRINT"VERSUCHEN MIT IHM ZU REDEN, INDEM DU"
18630 PRINT"' '":PRINT"EINTIPPST,      ABER POSITIVE"
18635 PRINT"ANTWORTEN SIND NICHT IMMER GARANTIERT."
18636 PRINT:PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18640 PRINT:PRINT"'Ƞ'":PRINT"KANN MIT":PRINT"''":PRINT"ABGEKUERZT WERDEN.
18645 PRINT"DASSELBE GILT AUCH FUER ALLE ANDEREN"
18650 PRINT"HIMMELSRICHTUNGEN.":PRINT:PRINT
18655 PRINT"DAS ZIEL DES SPIELES IST, INS"
18660 PRINT"20. JAHRHUNDERT ZURUECKZUKEHREN.":PRINT"VIEL SPASS!"
18670 PRINT" GANZ NUETZLICHE BEFEHLE SIND:":PRINT
18671 PRINT" - BEENDET SPIEL (FUER IMMER)
18673 PRINT" - SAVET SPIEL AUF DISK ODER CASS.
18675 PRINT" - ZEIGT EINE  DER MOEG-     LICHEN BEFEHLE."
18800 PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18810 PRINT:PRINT"WENN DU MIT EINIGEN 'SAETZEN'            HAST, DANN"
18820 PRINT"VERSUCHE ES MIT  DEUTSCHEN -"
18830 PRINT".":PRINT
18870 PRINT:PRINT:PRINT:PRINT"VIEL SPASS !":PRINT:PRINT
18890 INPUT"**** DRUECKE RETURN ZUM BEGINNEN ***";I$:PRINT"":PRINT:RETURN
18990 RETURN
19000 REM INITIALISION
19001 PRINT"WARTE BITTE. INITIALISIERE DATA."
19002 PRINT"WENN DU KEIN 12-MINUTEN-EI HABEN MOECH- TEST, DANN SCHALTE ";
19003 PRINT"LIEBER DEN HERD AUS."
19004 FORR=0TO62:READD:POKE832+R,D:NEXT
19005 FORA=1TO8:READDN$(A):NEXTA
19020 A=1
19025 FORB=0TO1:READLD$(A,B):NEXTB:IFLD$(A,0)<>""THENA=A+1:GOTO19025
19027 NL=A-1
19030 FORA=1TONL:FORB=1TO8:READLV%(A,B):NEXTB:READR%(A):NEXTA
19040 FORA=1TONL:L%(A)=0:NEXTA
19050 A=1
19060 READID$(A),IL%(A),IW(A),PR(A):IFIL%(A)<>-999THENA=A+1:GOTO19060
19065 NI=A-1
19067 FORA=1TO10:READPW$(A):NEXTA
19070 A=1
19071 LD$(35,0)=LD$(35,0)+"TEIL ZER-   STOERT HAT. UBERALL IST SCHUTT. DIE EBE-"
19072 LD$(35,0)=LD$(35,0)+"NE VERLIERT SICH IM NEBEL."
19075 READWD$(A),W%(A,0),W%(A,1):IFWD$(A)<>""THENA=A+1:GOTO19075
19077 LD$(34,0)=LD$(34,0)+"EN ODER AEHNLICHES AM EINGANG ZUR U-BAHN ZU SE- HEN."
19078 LD$(33,0)=LD$(33,0)+" BLOCKIERT IST."
19079 LD$(27,0)=LD$(27,0)+" UND IM NORDEN IST EINE KLEINE KAMMER."
19080 NW=A-1
19082 LD$(15,0)=LD$(15,0)+" DIE      STRASSE GEHT IM SUEDEN WEITER."
19083 LD$(16,0)=LD$(16,0)+"CHER IST   AUSEINANDERGEBROCHEN UND DIE MUENZEN    L"
19084 LD$(16,0)=LD$(16,0)+"IEGEN HERUM."
19085 L=1:T=1
19087 W=0:M=-119
19088 E=0:J=0:R=0
19089 FORRR=40960TO49151:POKERR,PEEK(RR):NEXT:POKE43846,157: REM DATA KONTROLLE
19090 POKE1,54:PRINT"":PRINT:INPUT"SPIEL LADEN? (J/N) ";I$
19092 DUMMY=RND(-TI) : REM RANDOM START
19093 PW=INT(RND(1)*10)+1
19096 CM%=INT(RND(1)*9999)
19097 RM=INT(RND(1)*900)+100
19100 IFLEFT$(I$,1)="J"THENGOSUB6500
19120 RETURN
19500 REM  SPRITE DATA
19510 DATA1,128,0,1,128,0,1,128,0,1,128,0,15,252,0,15,240,0,15,252,0,15,192,0,15
19520 DATA252,0,1,32,0,7,48,0,12,24,28,24,255,224,48,6,28,96,3,0,96,3,0,96,3,0
19530 DATA96,3,0,255,255,128,37,41,0,24,198,0
20000 REM  DATA
20001 REM
20002 REM
20005 DATA"ORD ","UED ","ST ","EST ","OCH ","UNTER ","N ","AUS "
20010 REM  #PLAETZE
20030 REM  PLATZ-BESCHR.-KURZ-BESCHR.
20040 DATADU BIST AUF DEM PARKPLATZ EINES EIN-    KAUFSZENTRUMS.
20041 DATADU BIST BEI DEN PARKPLAETZEN DES EIN-   KAUFSZENTRUMS.
20050 DATADU BIST IM EINKAUFSZENTRUM. NEBEN DIR   IST EIN COMPUTER-FACHGESCHAEFT.
20051 DATADU BIST IM EINKAUFSZENTRUM NEBEN DEM    COMPUTERLADEN.
20060 DATADU BIST IM COMPUTERGESCHAEFT.
20061 DATADU BIST IM COMPUTERLADEN.
20070 DATA"IM WESTEN IST EIN GUTES COMICBUCH GE-   SCHAEFT,IM OSTEN EIN RESTAURANT.
20071 DATADU BIST BEIM COMIC-LADEN UND RESTAURANT.
20080 DATA"ES IST EIN COMIC-BUCHLADEN, DER JEDEM   SAMMLER VON COMICS SCHMEICHELT."
20081 DATADU BIST IM COMIC-BUCHLADEN.
20085 REM  6:
20090 DATADU BIST IN EINEM RESTAURANT.
20091 DATADU BIST IM RESTAURANT.
20100 DATA"IM WESTEN IST EINE ARKADE, UND IM OSTEN EIN LEBENSMITTELLADEN."
20101 DATADU BIST BEI DER ARKADE UND DEM KAUFMANN.
20110 DATADU BIST IN DEM BOGENGANG.
20111 DATADU BIST IN DER ARKADE.
20120 DATAIM WESTEN IST EINE FLEISCHEREI UND IM   OSTEN EIN BEKLEIDUNGSGESCHAEFT.
20121 DATADU BIST ZWISCHEN DER FLEISCHEREI UND DEMBEKLEIDUNGSGESCHAEFT.
20130 DATADU BIST IN EINER FLEISCHEREI.
20131 DATADU BIST IN DER FLEISCHEREI.
20140 DATADU BIST IN EINEM BEKLEIDUNGSGESCHAEFT.
20141 DATADU BIST IN DEM BEKLEIDUNGSGESCHAEFT.
20150 DATADU BIST IN EINEM LEBENSMITTELGESCHAEFT.
20151 DATADU BIST IM LEBENSMITTELLADEN.
20160 DATADU BIST AUF EINER N-S STRASSE. EIN EIN- KAUFSZENTRUM IST IM WESTEN.
20161 DATADU BIST AUF DER STRASSE BEIM EINKAUFS-  ZENTRUM.
20170 DATANACH 100 METERN IST DIE STRASSE DURCH   HERABGEFALLENE STEINE BLOCKIERT.
20171 DATADU BIST AM ENDE DER STRASSE.
20180 DATA"DU BIST AN EINEN INFORMATIONSSTAND, DER VON EINEM ROBOTER BESETZT IST."
20181 DATADU BIST BEIM INFO-STAND.
20190 DATA"DU BIST IN EINER TELEFONZELLE. DAS TELE-FON IST KAPUTT, DER MUENZSPEI"
20191 DATADU BIST IN DER TELEFONZELLE.
20200 DATAI,I
20210 DATADU BIST IN EINER BUECHEREI.
20211 DATADU BIST IN DER BUECHEREI.
20220 DATAIM WESTEN IST EINE BUECHEREI UND IM OST-EN DIE STADTHALLE.
20221 DATADU BIST BEI DER BUECHEREI UND DER STADT-HALLE.
20230 DATADU BIST IM FOYER DER STADTHALLE. ES GIBTHIER EINE TREPPE.
20231 DATADU BIST IM FOYER DER STADTHALLE.
20240 DATADIE STRASSE ENDET HIER. EINE TREPPE     FUEHRT ZU EINER U-BAHN STATION.
20241 DATADU BIST BEI DER U-BAHN STATION.
20245 DATAS,STADTHALLE
20250 DATA"DU BIST IN EINEM KORRIDOR, DER ZU BUEROSIM OSTEN FUEHRT.
20251 DATADU BIST IM KORRIDOR.
20260 DATAES GIBT HIER EIN BUERO IM NORDEN UND    EINS IN SUEDEN.
20261 DATADU BIST ZWISCHEN ZWEI BUEROS.
20270 DATADU BIST IN EINEM BUERO.
20271 DATADU BIST IM BUERO.
20280 DATADU BIST IN EINEM BUERO.
20281 DATADU BIST IM BUERO.
20290 DATADU BIST IN EINEM KORRIDOR DES GEFAENG-  NISSES. EINE ZELLE IST IM SUEDEN
20291 DATADU BIST IM GEFAENGNISKORRIDOR.
20300 DATADU BIST IN EINER GEFAENGNISZELLE.
20301 DATADU BIST IN DER ZELLE
20310 DATADU BIST IN EINER KLEINEN KAMMER.
20311 DATADU BIST IN DER KAMMER.
20320 DATAS,MARKTSTRASSE
20330 DATAS,METRO UNIVERSITAET
20340 DATAS,ENDSVILLE
20350 DATA"DU BIST AUF EINER STRASSE, DIE IN BEIDENRICHTUNGEN DURCH TRUEMMER"
20351 DATADU BIST AUF EINER BLOKIERTEN STRASSE.
20360 DATADU BIST IN DER HAUPTHALLE DER METRO     UNIVERSITAET. ES SIND KEINE TUER
20361 DATADU BIST IM FOYER DER UNI.
20370 DATA"DU BIST IN EINER EBENE, WO EINE BOMBEN- EXPLOSION EINEN GANZEN STADT"
20371 DATADU BIST BEI DER UNTERGRUNDBAHN-STATION.
20380 DATADU STEHST VOR EINER TUER
20381 DATADU STEHST VOR EINER TUER
20390 DATA"DU BIS IN LABOR VON PROJEKT . SIEARBEITEN AN ZEITVERSCHIEBUNG."
20391 DATADU BIST IM LABORATORIUM.
20400 DATAT,T
20405 DATADU BIST AUF DER EBENE.
20406 DATADU BIST AUF DER EBENE.
20410 DATADU BIST BEI EINER TELEFONZELLE.
20411 DATADU BIST BEI EINER TELEFONZELLE.
20990 DATA"",""
21000 REM  BEWEGUNGEN, ROBOTER
21010 DATA0,0,13,0,0,0,2,0,0
21020 DATA7,4,0,0,0,0,3,1,0
21030 DATA0,0,0,0,0,0,0,2,1
21040 DATA2,0,6,5,0,0,0,0,0
21050 DATA0,0,0,0,0,0,0,4,1
21055 REM  6:
21060 DATA0,0,0,0,0,0,0,4,1
21070 DATA9,2,12,8,0,0,0,0,0
21080 DATA0,0,0,0,0,0,0,7,0
21090 DATA0,7,11,10,0,0,0,0,0
21100 DATA0,0,0,0,0,0,0,9,0
21110 DATA0,0,0,0,0,0,0,9,1
21120 DATA0,0,0,0,0,0,0,7,1
21130 DATA14,15,0,1,0,0,0,0,0
21140 DATA0,13,0,0,0,0,0,0,0
21150 DATA13,19,0,0,0,0,17,0,0
21160 DATA0,0,0,0,0,0,0,40,0
21170 DATA0,0,0,0,0,0,0,15,1
21180 DATA0,0,0,0,0,0,0,19,0
21190 DATA15,21,20,18,0,0,0,0,0
21200 DATA0,0,0,0,23,27,0,19,26
21210 DATA19,0,0,0,0,22,0,0,3
21220 DATA0,30,0,0,0,0,0,21,0
21225 DATA0,0,24,0,0,20,0,0,23
21230 DATA26,25,0,23,0,0,0,0,0
21240 DATA0,0,0,0,0,0,0,24,3
21245 DATA0,0,0,0,0,0,0,24,0
21250 DATA29,28,0,0,20,0,0,0,25
21260 DATA0,0,0,0,0,0,0,0,0
21270 DATA0,0,0,0,0,0,0,27,0
21280 DATA22,31,0,0,0,0,0,33,0
21290 DATA30,32,0,0,0,0,0,34,0
21300 DATA31,0,0,0,0,0,0,35,0
21310 DATA0,0,0,0,0,30,0,0,0
21320 DATA0,0,0,0,0,31,0,0,1
21330 DATA39,39,39,39,0,32,0,0,0
21340 DATA0,0,0,0,0,0,37,0,1
21350 DATA0,0,0,0,0,0,38,36,0
21360 DATA0,0,0,0,0,0,0,0,0
21370 DATA39,39,39,39,0,0,0,0,0
21380 DATA39,39,39,39,0,0,16,0,0
23000 REM GEGENSTAENDE
23030 DATAFLEISCHERMESSER,10,15,0
23040 DATAWAAGE,10,140,0
23050 DATANAHRUNGS PILLEN,12,1,10
23060 DATACOMMODORE 640 COMPUTER,3,40,10000
23070 DATAVIDEOSPIEL MASCHINE,8,-1,0
23080 DATAHERRENANZUG,11,6,995
23085 DATAKRAWATTE,11,.25,20
23090 DATACOMIC,5,.3,6
23100 DATALASER PISTOLE,14,3,0
23110 DATAMUENZEN,16,5,0
23120 DATABUCH,18,3,0
23130 DATAI.D. CARD,29,.01,0
23140 DATABRIEF,26,0.05,0
23150 DATAZERSTREUTE METALLSTUECKE,-1,15,0
23160 DATAZEITMASCHINE,37,2000,0
23990 DATA"",-999,-999,-999
23995 DATASESAM,SNARK,QUARK,BIRNBAUM,MONDSCHEIN,SCHUH,TRUTHAHN,WEIHNACHTEN
23996 DATATHORANIA,ROBOTWAR
24000 REM  WOERTER
24030 DATAN,1,101
24040 DATAS,1,102
24050 DATAO,1,103
24060 DATAW,1,104
24070 DATAH,1,105
24080 DATAR,1,106
24090 DATAIN,1,107
24100 DATARAUS,1,108
24110 DATANIMM,2,-1
24115 DATANEHME,2,-1
24120 DATAGEH,1,-1
24125 DATAGEHE,1,-1
24130 DATAWEG,3,-1
24140 DATALOOK,4,-1
24180 DATAINV,5,-1
24190 DATAQUIT,99,-1
24200 DATASAVE,6,-1
24220 DATAKAUF,10,-1
24225 DATAKAUFE,10,-1
24230 DATAWIEG,7,-1
24235 DATAWIEGE,7,-1
24240 DATALES,8,-1
24245 DATALESE,8,-1
24255 DATAUNT,8,-1
24256 DATAUNTERSUCHE,8,-1
24257 DATAUNTERSUCH,8,-1
24260 DATAMESSER,-1,1
24261 DATAFLEISCHERMESSER,-1,1
24270 DATAWAAGE,-1,2
24280 DATAPILLEN,-1,3
24290 DATACOMMODORE,-1,4
24300 DATACOMPUTER,-1,4
24315 DATASPRICH,11,-1
24320 DATABUCH,-1,11
24325 DATAVIDEOSPIEL,-1,5
24330 DATASPIEL,12,-1
24335 DATASPIELE,12,-1
24340 DATAANZUG,-1,6
24345 DATAHERRENANZUG,-1,6
24350 DATAKRAWATTE,-1,7
24360 DATACOMIC,-1,8
24370 DATAESS,13,-1
24375 DATAESSE,13,-1
24380 DATABRICH,14,-1
24382 DATABRECHE,14,-1
24383 DATAENTFERNE,14,-1
24384 DATABRECHE AUS,14,-1
24385 DATARENN WEG,14,-1
24386 DATABRICH AUS,14,-1
24387 DATARENNE WEG,14,-1
24390 DATAHAU,14,-1
24391 DATALAUF WEG,14,-1
24395 DATAVERSCHWINDE,14,-1
24400 DATAPISTOLE,-1,9
24406 DATALASER,-1,9
24410 DATAMUENZEN,-1,10
24420 DATAGELD,-1,10
24430 DATAKASTEN,-1,10
24435 DATASPEICHER,-1,10
24440 DATASCHIESS,9,-1
24445 DATAERSCHIESS,9,-1
24450 DATAANGRIFF,15,-1
24455 DATAGREIF,15,-1
24460 DATAI.D.,-1,12
24465 DATAIDENTITY,-1,12
24470 DATACARD,-1,12
24475 DATAKARTE,-1,12
24480 DATABRIEF,-1,13
24490 DATASTUECKE,-1,14
24495 DATAMETALL,-1,14
24500 DATAOEFFNE,16,-1
24510 DATASCHLIESSE,16,-1
24515 DATAMACHE,16,-1
24520 DATAHILF,17,-1
24530 DATAAN,18,-1
24540 DATASTANGEN,-1,200
24545 DATASTANGE,-1,200
24550 DATASTAEBE,-1,200
24555 DATASTAB,-1,200
24895 REM ***** UNABGEKUERTZT
24900 DATANORD,1,101
24910 DATASUED,1,102
24920 DATAOST,1,103
24930 DATAWEST,1,104
24940 DATAHOCH,1,105
24950 DATARUNTER,1,106
24960 DATAINVENTAR,5,-1
24980 DATAAUS,1,108
24990 REM ***** WEITERE BEFEHLE UND                     WOERTER
25240 REM **** DEUTSCH
25250 DATAWERF,3,-1
25270 DATASCHAU,4,-1
25280 DATAUMSCHAU,4,-1
25330 DATAZEIG,4,-1
25350 DATAINVENTAR,5,-1
29998 DATA"",-999,-999
29999 REM ******************************
30000 INPUTA$:IFLEFT$(A$,1)<>"J"THENRETURN
30005 PRINT"ROBOTER: WAS SOLL ICH IHNEN ZEIGEN?":INPUTA$:FORR=1TOLEN(A$)
30006 IFMID$(A$,R,1)="K"THENIFMID$(A$,R,5)="KARTE"THEN30029
30008 NEXTR
30009 FORR=1TOLEN(A$)
30010 IFMID$(A$,R,1)="P"THENIFMID$(A$,R,4)="PLAN"THEN30029
30011 NEXTR
30028 PRINT"ROBOTER: KRZZFLSCH, I..I..INFORMATIONS- STAND K..K..A..PUTT.":RETURN
30029 PRINT:PRINT"EINE WAND SCHIEBT SICH LANGSAM HOCH UND DU SIEST EINE ANGESE";
30030 PRINT"NGTE KARTE:
30035 FORR=1TO1000:NEXTR:POKEVC+17,PEEK(VC+17)-64
30040 PRINT"         
30050 PRINT"                 
30060 PRINT"          E   
30070 PRINT"             S   
30080 PRINT"               
30090 PRINT"              U      
30100 PRINT"          ݿ       
30110 PRINT"          ݿ   M֦  
30120 PRINT"          ɿ       
30130 PRINT"             U֦  
30140 PRINT"          ݿ           
30150 PRINT"          ʮ        צ֦ 
30160 PRINT"              E 
30170 PRINT"            ɿ
30180 PRINT"                 
30190 PRINT"MITNEHMEN GEHT NICHT;KARTE IST FESTGENA-GELT."
30195 INPUT"DRUECKE RETURN";I$
30200 PRINT:PRINT"DIE WAND SCHIEBT SICH WIEDER ZU."
30210 FORR=1TO10:PRINT"":FORRR=1TO200:NEXT:NEXT:PRINT""
30900 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
31000 PRINT"ZUM ANSCHAUEN DES COMICS DRUECKE 'A'    SONST NUR 'RETURN'."
31005 INPUTA$:IFA$<>"A"THENRETURN
31006 PRINT:PRINT"VIEL SPASS!":POKEVC+17,PEEK(VC+17)-64
31040 RESTORE:FORR=0TO62:READD:POKE832+R,D:NEXT
31050 VC=53248:POKE2040,13:POKEVC,0:POKEVC+1,0:POKEVC+21,1:POKEVC+23,1:POKEVC+29,1
31060 PRINT"":FORQ=1TO25:PRINT" ";:NEXT
31100 PRINT"":PRINT,"           "
31105 PRINT," SUPER-    "
31110 PRINT," ROBOT  "
31120 PRINT,"     "
31130 PRINT,"     "
31140 PRINT,"        "
31150 PRINT,"        "
31160 PRINT,"     "
31170 PRINT,"     "
31180 PRINT,"        "
31190 PRINT,"        "
31200 PRINT,"     "
31210 PRINT,"     "
31220 PRINT,"        "
31230 PRINT,"           "
31240 FORR=1TO6:FORD=1TO2:PRINTTAB(24+R)" ":NEXT:PRINT"":NEXT
31250 FORR=1TO6:FORD=1TO2:PRINTTAB(30+R)" ":NEXT:PRINT"":NEXT
31260 FORQ=36TO39:PRINTTAB(Q)" ";:NEXT:FORQ=1TO1000:NEXT
31270 POKEVC+1,136:FORQ=0TO60:POKEVC,Q:FORR=0TO10*Q-400:NEXT:FORR=1TO9:NEXT:NEXT
31290 P=PEEK(VC+33):FORQ=1TO5:POKEVC+33,2
31300 FORR=1TO70:NEXT:POKEVC+33,P:FORR=1TO70:NEXT:NEXT
31310 FORQ=15TO1STEP-1:FORR=1TO12:POKE1024+9+R+40*Q,32:NEXT:IFQ=13THEN31330
31320 NEXT:GOTO31340
31330 PRINT"B U M M !" :NEXT
31340 FORQ=1TO1000:NEXT:PRINT"         "
31350 FORQ=60TO255:POKEVC,Q:FORR=1TOQ-Q/1.25:NEXT:NEXT
31360 PRINT""TAB(21)"HUH ?";:FORQ=1TO500:NEXT:PRINT"     "
31370 FORQ=1TO30:NEXT:PRINT""TAB(21)"AAAAAAAHHH!"
31380 FORQ=136TO168:POKEVC+1,Q:FORR=1TO129-(Q-136)*4:NEXT:NEXT
31390 FORQ=62TO0STEP-1:POKE832+Q,RND(1)*256:NEXT:FORQ=0TO62:POKE832+Q,0
31400 FORR=1TO10:NEXT:NEXT
31410 POKEVC+21,0                  
31420 PRINT""TAB(21):FORQ=1TO21:PRINTMID$("           ",Q,1);
31430 FORR=1TO50:NEXT:NEXT:PRINT""
32040 DATAWAAGE,10,140,0
33900 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
40000 FORT=1TO2000:NEXT
40010 POKE1,55:POKEVC+17,PEEK(VC+17)-64
40020 END
50000 REM  VIDIOSPIEL
50010 INPUT"DRUECKE RETURN.";I$:POKEVC+17,PEEK(VC+17)-64
50800 POKE650,128:POKE53280,254:POKE53281     ,254:POKE646,0:PRINTCHR$(8)
51100 PRINT"******************************************************************";
51300 PRINT"************************   MASTER - KILLER   ********************";
51400 PRINT"*****************************             PUNKTETABELLE : "
51500 PRINT"    ձ = 100  PUNKTE      J = LINKS"
51600 PRINT"     = 500 PUNKTE       K = RECHTS"
51700 PRINT"    ֮ = IHRE STATION     S = SCHUSS"
51750 PRINT"       DIE HOEHE DES RAUMSCHIFFES"
51800 PRINT""
51950 PRINT"    1.  SPIEL   :  DRUECKE 'SPACE'"
52000 FORI=35TO0STEP-1:PRINTSPC(I)" "     :GETA$:IFA$=" "THEN53000
52100 FORR=1TO60:NEXT:NEXTI
52200 FORI=0TO35:PRINTSPC(I)" ":GETA$     :IFA$=" "THEN53000
52300 FORR=1TO60:NEXTR:NEXTI:GOTO52000
53000 PRINT"":POKE53280,0:POKE53281,0
53100 XQ=RND(1)*38:Y=0:VI=1024:FA=55296:VU=1984:FU=56256:Z=RND(1):TR=0
53120 IFZ>.9THENGOTO61400:
53130 S=S-1:Y=Y+1:POKEVI+Y-1,32:POKEVI+Y,     85:POKEVI+Y+1,113:POKEVI+Y+2,73
53135 POKEFA+Y,5:POKEFA+Y+1,5:POKEFA+Y+2,     5
53137 IFY>900THEN60000
53140 GETA$
53150 IFA$="J"THENXQ=XQ-1
53160 IFA$="K"THENXQ=XQ+1
53170 IFA$="S"ANDS<-2THENS=22
53180 IFXQ>38THENXQ=XQ-1
53190 IFXQ<1THENXQ=XQ+1
53900 POKEVU+XQ-2,32:POKEVU+XQ+2,32:POKEVU+XQ-41,32:POKEVU+XQ-39,32
54000 POKEVU+XQ-1,112:POKEVU+XQ,86:POKEVU+XQ+1,110:POKEVU+XQ-40,66
54010 POKEFU+XQ-1,10:POKEFU+XQ,10:POKEFU+XQ+1,10:POKEFU+XQ-40,13
54700 IFS=22THENU=XQ
54750 IFS=22THEN62000
54800 IFS>-2THENTR=PEEK(VI+40*S+U)
54900 IFTR=85ORTR=113ORTR=73ORTR=109ORTR=     114ORTR=125THEN56900
55000 IFS>-2THENPOKEVI+40*S+U,66:POKEVI+4     0*S+40+U,32:POKEFA+40*S+U,3
56000 GOTO53120
56900 POKE53280,7:POKE53281,7
56901 FORJ=15TO0STEP-1
56902 POKEQ,J:POKECC,15:POKEFH,90:POKEFL,200:POKEW,129
56903 NEXTJ
56904 POKEW,0:POKECC,0
57000 POKEVI+40*S+U-41,85:POKEVI+40*S+U-4     0,67
57100 POKEVI+40*S+U-39,73:POKEVI+40*S+U-1,66:POKEVI+40*S+U,224:POKEVI+40*S+U+1,66
57200 POKEVI+40*S+U+41,75:POKEVI+40*S+U+4     0,67:POKEVI+40*S+U+39,74
57400 POKEFA+40*S+U-41,7:POKEFA+40*S+U-40     ,7
57500 POKEFA+40*S+U-39,7:POKEFA+40*S+U-1,     7:POKEFA+40*S+U,7:POKEFA+40*S+U+1,7
57600 POKEFA+40*S+U+41,7:POKEFA+40*S+U+40     ,7:POKEFA+40*S+U+39,757700 POKE53280,0:POKE53281,0
57800 PRINT"":FORR=1TO8:NEXT
58250 IFF=66ORG=66THEN61100
58260 IFZ<.9THENSP=SP+90+INT((1000-Y)/10)
58265 IFZ>.9THENSP=SP+490+INT((100      0-Y)/10)
58300 PRINT"   SPIELER HAT NUN :"
58400 PRINT"   ";SP" PUNKTE":SZ=SZ+1:IFSZ>3THEN63000
58500 PRINT"    NAECHSTES SPIEL"
58600 PRINT"    DRUECKE 'SPACE'"
58700 GETA$:IFA$=""THEN58700
58800 IFA$=" "THEN59000
58900 GOTO58700
59000 S=-1:F=0:G=0:GOTO53000
60000 F=PEEK(VI+Y+3):G=PEEK(VI+Y+4):IFF=      66ORG=66THEN61000
60001 GOTO53140
61000 S=0:U=Y+3:GOTO6900
61100 PRINT"     SIE HABEN SICH IHR RAUMSCHIFF"
61200 PRINT"     ZERSTOEREN LASSEN !"
61250 PRINT"    DAS GIBT 1000 PUNKTE ABZUG !"
61300 SP(B)=SP(B)-1000:F=0:GOTO58300
61400 S=S-1:Y=Y+2:POKEVI+Y-2,32:POKEVI+Y      -1,32
61405 POKEVI+Y,109:POKEVI+Y+1,114:POKEVI      +Y+2,125
61410 GOTO53135
62000 SI=54272:FL=SI:FH=SI+1:TL=SI+2:TH=SI+3:W=SI+4:CC=SI+5:D=SI+6:Q=SI+24
62001 FORE=15TO0STEP-1
62002 POKEQ,E:POKECC,15:POKED,0:POKEFH,10:POKEFL,50:POKEW,129
62003 NEXTE
62004 POKEW,0:POKECC,0
62005 GOTO53120
63000 PRINT"         G A M E    O V E R "
63001 FORR=1TO2000:NEXT:PRINT""CHR$(151):POKE53248+32,12:POKE53248+33,12
63010 POKE650,0:PRINTCHR$(9)
63020 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
READY.

50000 REM  VIDIOSPIEL
50010 INPUT"DRUECKE RETURN.";I$:POKEVC+17,PEEK(VC+17)-64
50800 POKE650,128:POKE53280,254:POKE53281     ,254:POKE646,0:PRINTCHR$(8)
51100 PRINT"******************************************************************";
51300 PRINT"************************   MASTER - KILLER   ********************";
51400 PRINT"*****************************             PUNKTETABELLE : "
51500 PRINT"    ձ = 100  PUNKTE      J = LINKS"
51600 PRINT"     = 500 PUNKTE       K = RECHTS"
51700 PRINT"    ֮ = IHRE STATION     S = SCHUSS"
51750 PRINT"       DIE HOEHE DES RAUMSCHIFFES"
51800 PRINT""
51950 PRINT"    1.  SPIEL   :  DRUECKE 'SPACE'"
52000 FORI=35TO0STEP-1:PRINTSPC(I)" "     :GETA$:IFA$=" "THEN53000
52100 FORR=1TO60:NEXT:NEXTI
52200 FORI=0TO35:PRINTSPC(I)" ":GETA$     :IFA$=" "THEN53000
52300 FORR=1TO60:NEXTR:NEXTI:GOTO52000
53000 PRINT"":POKE53280,0:POKE53281,0
53100 XQ=RND(1)*38:Y=0:VI=1024:FA=55296:VU=1984:FU=56256:Z=RND(1):TR=0
53120 IFZ>.9THENGOTO61400:
53130 S=S-1:Y=Y+1:POKEVI+Y-1,32:POKEVI+Y,     85:POKEVI+Y+1,113:POKEVI+Y+2,73
53135 POKEFA+Y,5:POKEFA+Y+1,5:POKEFA+Y+2,     5
53137 IFY>900THEN60000
53140 GETA$
53150 IFA$="J"THENXQ=XQ-1
53160 IFA$="K"THENXQ=XQ+1
53170 IFA$="S"ANDS<-2THENS=22
53180 IFXQ>38THENXQ=XQ-1
53190 IFXQ<1THENXQ=XQ+1
53900 POKEVU+XQ-2,32:POKEVU+XQ+2,32:POKEVU+XQ-41,32:POKEVU+XQ-39,32
54000 POKEVU+XQ-1,112:POKEVU+XQ,86:POKEVU+XQ+1,110:POKEVU+XQ-40,66
54010 POKEFU+XQ-1,10:POKEFU+XQ,10:POKEFU+XQ+1,10:POKEFU+XQ-40,13
54700 IFS=22THENU=XQ
54750 IFS=22THEN62000
54800 IFS>-2THENTR=PEEK(VI+40*S+U)
54900 IFTR=85ORTR=113ORTR=73ORTR=109ORTR=     114ORTR=125THEN56900
55000 IFS>-2THENPOKEVI+40*S+U,66:POKEVI+4     0*S+40+U,32:POKEFA+40*S+U,3
56000 GOTO53120
56900 POKE53280,7:POKE53281,7
56901 FORJ=15TO0STEP-1
56902 POKEQ,J:POKECC,15:POKEFH,90:POKEFL,200:POKEW,129
56903 NEXTJ
56904 POKEW,0:POKECC,0
57000 POKEVI+40*S+U-41,85:POKEVI+40*S+U-4     0,67
57100 POKEVI+40*S+U-39,73:POKEVI+40*S+U-1,66:POKEVI+40*S+U,224:POKEVI+40*S+U+1,66
57200 POKEVI+40*S+U+41,75:POKEVI+40*S+U+4     0,67:POKEVI+40*S+U+39,74
57400 POKEFA+40*S+U-41,7:POKEFA+40*S+U-40     ,7
57500 POKEFA+40*S+U-39,7:POKEFA+40*S+U-1,     7:POKEFA+40*S+U,7:POKEFA+40*S+U+1,7
57600 POKEFA+40*S+U+41,7:POKEFA+40*S+U+40     ,7:POKEFA+40*S+U+39,7
57700 POKE53280,0:POKE53281,0
57800 PRINT"":FORR=1TO8:NEXT
58250 IFF=66ORG=66THEN61100
58260 IFZ<.9THENSP=SP+90+INT((1000-Y)/10)
58265 IFZ>.9THENSP=SP+490+INT((100      0-Y)/10)
58300 PRINT"   SPIELER HAT NUN :"
58400 PRINT"   ";SP" PUNKTE":SZ=SZ+1:IFSZ>3THEN63000
58500 PRINT"    NAECHSTES SPIEL"
58600 PRINT"    DRUECKE 'SPACE'"
58700 GETA$:IFA$=""THEN58700
58800 IFA$=" "THEN59000
58900 GOTO58700
59000 S=-1:F=0:G=0:GOTO53000
60000 F=PEEK(VI+Y+3):G=PEEK(VI+Y+4):IFF=      66ORG=66THEN61000
60001 GOTO53140
61000 S=0:U=Y+3:GOTO6900
61100 PRINT"     SIE HABEN SICH IHR RAUMSCHIFF"
61200 PRINT"     ZERSTOEREN LASSEN !"
61250 PRINT"    DAS GIBT 1000 PUNKTE ABZUG !"
61300 SP(B)=SP(B)-1000:F=0:GOTO58300
61400 S=S-1:Y=Y+2:POKEVI+Y-2,32:POKEVI+Y      -1,32
61405 POKEVI+Y,109:POKEVI+Y+1,114:POKEVI      +Y+2,125
61410 GOTO53135
62000 SI=54272:FL=SI:FH=SI+1:TL=SI+2:TH=SI+3:W=SI+4:CC=SI+5:D=SI+6:Q=SI+24
62001 FORE=15TO0STEP-1
62002 POKEQ,E:POKECC,15:POKED,0:POKEFH,10:POKEFL,50:POKEW,129
62003 NEXTE
62004 POKEW,0:POKECC,0
62005 GOTO53120
63000 PRINT"         G A M E    O V E R "
63001 FORR=1TO2000:NEXT:PRINT""CHR$(151):POKE53248+32,12:POKE53248+33,12
63010 POKE650,0:PRINTCHR$(9)
63020 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
READY.

1 REM
2 REM  PLANET.OF.THE.ROBOTS
3 REM  BY DANIEL TOBIAS   11/81
4 REM  AN ADVENTURE-STYLE GAME
5 REM
6 REM  MODEFIKATION AUF CBM 64                 GRAFISCHE VERBESSERUNGEN
7 REM  DEUTSCHE UEBERSETZUNG                           UND
8 REM  VERTRIEB IN DEUTSCHLAND
9 REM                                           **********************
10 REM   THORANIA SOFTWARE                       SCHULENBURGALLEE 140
11 REM   3180 WOLFSBURG 1                       **********************
12 REM                                             5.5. - 17.5.1983
13 REM     ----------------             14 REM
15 PRINT"":NA$="ROBOT-":VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11
16 DIMLV%(100,8),LD$(100,1),R%(100),ID$(50),IL%(50),PR(50),IW(50),L%(100)
17 DIMWD$(150),W%(150,1),FW%(1)
18 PRINTCHR$(151):POKE53248+32,12:POKE53248+33,12
20 GOSUB18000:GOSUB19000
60 PRINT"":PRINT
100 REM  START
108 XX=1
110 IFXX=1THENGOSUB1000
120 GOSUB500
125 XX=XX+1:IFXX>5THENXX=1
130 IFFW%(0)=0THENPRINT"WAS ?":GOTO110
140 ONFW%(0)GOSUB2000,3000,4000,5000,5500,6000,7000,8000,9000,9500
142 IFFW%(0)>10THENONFW%(0)-10GOSUB13000,13500,14500,15000,15500,16000,16500,10000
145 IFFW%(0)=99THENPRINT"ENDE NACH"T"BEWEGUNGEN.":GOTO40000
150 T=T+1:GOTO110
500 REM  EINGABE HANDLUNG
502 POKE649,1:POKE631,0
505 I$="":FW%(0)=0:FW%(1)=0:PRINT:INPUT"-->";I$
515 IFI$=""THENPRINT"":GOTO505
520 WD$="":A=1
530 IFMID$(I$,A,1)=" "THEN600
540 WD$=WD$+MID$(I$,A,1)
550 A=A+1:IFA<=LEN(I$)THEN530
600 REM  WORT GEFUNDEN
610 FORB=1TONW:IFWD$(B)=WD$THENGOSUB650
620 NEXTB:WD$="":A=A+1
630 IFA>LEN(I$)THENRETURN
640 GOTO530
650 FORC=0TO1
660 IFW%(B,C)>=0THENFW%(C)=W%(B,C)
670 NEXTC:RETURN
1000 REM PRINT BESCHREIBUNG
1002 IFLD$(L,0)="S"THENGOSUB12000
1010 PRINT:PRINTLD$(L,L%(L))
1011 IFL=28ANDJ=0THENPRINT"ES GIBT EINE TUER MIT GITTERSTAEBEN."
1012 IFL=28ANDJ<>0THENPRINT"DIE STAEBE SIND ABGEBROCHEN UND GEBEN   DEN WEG";
1013 IFL=28ANDJ<>0THENPRINT"NACH DRAUSSEN FREI."
1014 PRINT:L%(L)=1:POKEVC+34,7
1015 L%(L)=1
1020 PRINT"OFFENE WEGE: ":FORA=1TO8:IFLV%(L,A)<>0THENPRINTDN$(A);
1025 NEXTA:PRINT
1040 PRINT"SICHTBARE GEGENSTAENDE:":X=0:FORA=1TONI
1060 IFIL%(A)=LTHENPRINT" "ID$(A);:X=1:IFPR(A)>0ANDR%(L)=1THEN1062
1061 GOTO1065
1062 PRINT" (PREIS: $"PR(A)")";
1065 IFIL%(A)=LTHENPRINT
1070 NEXTA
1080 IFX=0THENPRINT"ES SIND KEINE DA."
1085 IFR%(L)<>0THENPRINT
1090 IFR%(L)=1THENPRINT"EIN ANGESTELLTER ROBOTER IST DA."
1100 IFR%(L)>20ANDR%(L)<29THENPRINT"EIN WACH-ROBOTER IST DA."
1110 IFR%(L)=3THENPRINT"EIN WUETENDER UND RASENDER ROBOTER IST  DA."
1111 IFR%(L)=3THENPRINT" !"
1120 IFT-E>=100THENPRINT:PRINT"DU WIRST LANGSAM !"
1490 RETURN
2000 REM  BEWEGUNGEN
2005 IFFW%(1)<101ORFW%(1)>108THENPRINT"GEHE WOHIN?":RETURN
2010 X=LV%(L,FW%(1)-100)
2020 IFX<0ORX>NLTHENPRINT"DALANG GEHT'S IM MOMENT NICHT.":RETURN
2025 IFL=28ANDI$="BRICH AUS"THEN15000
2030 IFX=0THENPRINT"DU KANNST DA NICHT LANG GEHEN.":RETURN
2035 IFR%(L)=3THENPRINT"ROBOTER: VERSUCHST WOHL ZU ENTWISCHEN,  WAS?   ";
2036 IFR%(L)=3THENPRINT"DAS WIRD NICHT KLAPPEN!":FORR=1TO1000:NEXT
2037 IFR%(L)=3THENPRINT:PRINT"             ZAFLAPP !":FORR=1TO1000:NEXT:PRINT
2038 IFR%(L)=3THENPRINT"DU BIST TOD!":PRINT:PRINT"-SCHLUSS NACH"T"VERSUCHEN.-"
2039 IFR%(L)=3THENGOTO40000
2040 IFX=6ANDIL%(7)<>0THENPRINT"ROBOTER: TUT MIR LEID, ABER NACH DEN    VORSCHRIFTE";
2041 IFX=6ANDIL%(7)<>0THENPRINT"N MUESSEN SIE EINE KRAWATTE  TRAGEN.":RETURN
2042 IFL=6ANDR<>0THENPRINT"ROBOTER: TUT MIR LEID, ABER SIE SIND    NICHT VER";
2043 IFL=6ANDR<>0THENPRINT"TRAUENSWUERDIG. SIE DUERFEN DA NICHT REIN !":RETURN
2045 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT"ROBOTER: I.D. KARTE AKZEPTIERT";
2046 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT". SIE     KOENNEN PASSIEREN. ";
2047 IFR%(L)=20+FW%(1)-100ANDIL%(12)=0THENPRINT"GUTEN TAG, MR. SMITH.":GOTO2060
2050 IFR%(L)=20+FW%(1)-100THENPRINT"ROBOTER: TUT MIR LEID,ABER OHNE I.D.KAR-T";
2051 IFR%(L)=20+FW%(1)-100THENPRINT"E DARF ICH SIE DA NICHT REINLASSEN.":RETURN
2060 REM
2065 IFL=39ANDX=39ANDRND(1)<.35THENPL=1-PL:X=35:IFPL=0THENX=40
2070 IFX=17THENPRINT"ROBOTER:KANN ICH IHNEN BEHILFLICH SEIN?"
2071 IFX=17THENGOSUB30000:RETURN
2080 IFLD$(X,0)="S"THENGOSUB12000:RETURN
2090 IFL=36ANDX=37THENINPUT"GEBE KOMBINATION EIN:";A$
2091 IFL=36ANDX=37THENIFVAL(A$)<>CM%THENPRINT"LEIDER FALSCH!":RETURN
2100 IFX=38THEN14000
2200 L=X:XX=1:RETURN
3000 REM  AUFHEBEN
3005 IFFW%(1)=0ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
3006 IFIL%(FW%(1))=0THENPRINT"DU TRAEGST ES BEREITS!":RETURN
3007 IFIL%(FW%(1))<>LTHENPRINT"DAS GIBT'S HIER NICHT.":RETURN
3009 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"ROBOT: SIE KOENNEN ES NICHT NEHMEN, OHN";
3010 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"EDAFUER ZU ZAHLEN. KAUFEN SIE ES, WENN";
3011 IFPR(FW%(1))>0ANDR%(L)=1THENPRINT"   SIE ES HABEN WOLLEN.":RETURN
3015 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"ZU SCHWER. DU MUSST ERST";
3016 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"EINMAL ETWAS    FALLEN L";
3017 IFWT+IW(FW%(1))>150ANDIW(FW%(1))<=150THENPRINT"ASSEN.":RETURN
3020 IFIW(FW%(1))>150THENPRINT"ZU SCHWER ZUM HOCHHEBEN FUER DICH.":RETURN
3030 IFIW(FW%(1))<0THENPRINT"ES IST AUS SICHERHEITSGRUENDEN FESTGE-  SCHRAUBT":RETURN
3040 IL%(FW%(1))=0=WT=WT+IW(FW%(1))
3045 PRINT"OK."
3050 IFFW%(1)=10THENM=ABS(M)
3060 RETURN
4000 REM  FALLENLASSEN
4010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"DU TRAEGST ES ABER NICHT!":RETURN
4020 IFIL%(FW%(1))<>0THENPRINT"DU TRAEGST ES ABER NICHT!":RETURN
4030 IL%(FW%(1))=L:WT=WT-IW(FW%(1))
4040 PRINT"OK."
4042 IFL=39THENPRINT"ES RUTSCHT IN EINE SPALTE DER RUINEN UND IST WEG."
4043 IFL=39THENIL%(FW%(1))=-1
4045 IFFW%(1)=10THENM=-ABS(M)
4050 RETURN
5000 REM  UMSCHAUEN
5010 XX=1:L%(L)=0:RETURN
5500 REM  INVENTAR
5510 X=0:PRINT"DU SCHLEPPST MIT DIR 'RUM:":FORA=1TONI
5525 IFA=10THEN5540
5530 IFIL%(A)=0THENPRINT" "ID$(A):X=1
5540 NEXTA
5545 IFM>0THENPRINT" $"M" IN BAR.":X=1
5550 IFX=0THENPRINT"NICHTS."
5560 RETURN
6000 REM  SAVE SPIEL
6010 INPUT"SPIEL #";A
6016 INPUT"DISK ODER KASSETTE (D/K) ";A$
6017 IFA$<>"D"ANDA$<>"K"THEN6016
6018 IFA$="D"THENAA=8:GOTO6020
6019 AA=1
6020 OPEN1,AA,1,NA$+STR$(A)
6030 PRINT#1,L:FORB=1TONI:PRINT#1,IL%(B):NEXTB:PRINT#1,WT:PRINT#1,T
6050 FORB=1TONL:PRINT#1,R%(B):NEXTB:PRINT#1,M:PRINT#1,E
6060 FORB=1TONI:PRINT#1,PR(B):NEXTB
6070 PRINT#1,CM%:PRINT#1,R:PRINT#1,J
6080 PRINT#1,PW:PRINT#1,RM
6090 CLOSE1:RETURN
6500 REM  LOAD SPIEL
6510 INPUT"SPIEL #";A
6515 IFA<0THEN6510
6516 INPUT"DISK ODER KASSETTE (D/K) ";A$
6517 IFA$<>"D"ANDA$<>"K"THEN6516
6518 IFA$="D"THENAA=8:GOTO6520
6519 IFA$="K"THENAA=1:GOTO6520
6520 OPEN1,AA,0,NA$+STR$(A)
6530 INPUT#1,L:FORB=1TONI:INPUT#1,IL%(B):NEXTB:INPUT#1,WT:INPUT#1,T
6550 FORB=1TONL:INPUT#1,R%(B):NEXTB:INPUT#1,M:INPUT#1,E
6560 FORB=1TONI:INPUT#1,PR(B):NEXTB
6570 INPUT#1,CM%:INPUT#1,R:INPUT#1,J
6575 IFJTHENLV%(28,8)=27
6580 INPUT#1,PW:INPUT#1,RM:CLOSE1:RETURN
7000 REM  WIEGEN
7010 IFIL%(2)<>LANDIL%(2)<>0THENPRINT"ES GIBT KEINE WAAGE.":RETURN
7020 IFFW%(1)=2THENPRINT"DU KANNST SIE NICHT AUF SICH SELBER WIEGEN.":RETURN
7030 IFFW%(1)<1ORFW%(1)>NITHENPRINT"DIESEN GEGENSTAND GIBT'S HIER NICHT.":RETURN
7040 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"DIESEN GEGENSTAND GIBT'S HIER ";
7041 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"NICHT.":RETURN
7050 PRINT"ES WIEGT ";IW(FW%(1));"PFUND."
7060 RETURN
8000 REM  LESEN
8005 IFFW%(1)=200THENPRINT"DIE GITTERSTAEBE SEHEN ROSTIG UND"
8006 IFFW%(1)=200THENPRINT"WACKELIG AUS.":RETURN
8010 IFFW%(1)<1ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
8020 IFIL%(FW%(1))<>LANDIL%(FW%(1))<>0THENPRINT"GIBT'S HIER NICHT.":RETURN
8030 IFFW%(1)=5THENPRINT"DAS SCHILD BEDEUTET: WERFE $2.50 EIN.":RETURN
8050 IFFW%(1)=10THENPRINT"ES SIND VOR ALLEM DOLLAR MUENZEN, ABER  ES GIBT ";
8051 IFFW%(1)=10THENPRINT"AUCH EIN PAAR $2.50 STUECKE.":RETURN
8060 IFFW%(1)=4THENPRINT"ER HAT EIN MODEM MIT ANSCHLUSS AN DIE   BEZIRKSREGIERNG.":RETURN
8070 IFFW%(1)=8THENPRINT"ES IST DAS ABENTEUER VON SUPERROBOT.":GOSUB31000:RETURN
8080 IFFW%(1)=12THENPRINT"ES GEHOERT DEM SICHERHEITSBEAMTEN       BILL SMITH ";
8081 IFFW%(1)=12THENPRINT"UND HAT HOECHSTE VOLLMACHTEN.";:RETURN
8090 IFFW%(1)=14THENPRINT"ES SIND DIE UEBERRESTE DES FLEISCHERMES-SERS.":RETURN
8100 IFFW%(1)=11THEN8200
8110 IFFW%(1)=13THEN8300
8190 PRINT"NICHTS INTERESANTES.":RETURN
8200 REM  COMPUTER
8205 POKEVC+34,5:PRINT"                 :"
8206 PRINT"**        **              "
8210 PRINT:PRINT"SIE KOENNEN MIT JEDEM COMPUTER, DER MIT EINEM MODEM AUSGERUESTET IST";
8211 PRINT", DIE DATEN DER BEZIRKSREGIERUNG ABRUFEN."
8212 PRINT"MAN BRAUCHT NUR FOLGENDES EINZUGEBEN:"
8220 PRINT" >  1-12-1"
8230 PRINT"DANN WAEHLT MAN DIE DATEI DER BEZIRKSRE-GIERUNG AUS.[ ERMEN-ENG.";
8231 PRINT"=(BEZIRKS) -REGIERUNG ]":PRINT" >  "
8240 PRINT"SIE WERDEN NUN VOM COMPUTER NACH DEM    NAMEN DES GEWUENSCHTEN ";
8241 PRINT"FILES GEFRAGT.":PRINT"EIN FILE ZU DEM SIE ZUGANG HABEN HEISST  >";
8242 PRINT"  ":PRINT"UND BEINHALTET DIE GEGENWAERTIGE BE-    VOELKERUNGSTRUKTUR";
8243 PRINT" DER U.S.A.":PRINT"VIEL SPASS."
8260 RETURN
8300 REM  BRIEF
8305 POKEVC+34,8:PRINT"          ԠϠРӠŠàҠŠ"
8310 PRINT"AN DIE ARBEITER DES PROJEKTES 
8320 PRINT:PRINT"DIE GEGENWAERTIGE  DER TUER  DES RAUMES "RM" STEHT IN DER ";
8321 PRINT"DATEI":PRINT"DER BEZIRKSREGIERUNG AUF DEM FILE MIT   DEM NAMEN ''."
8322 PRINT"DAS PASSWORD DES FILES IST '"PW$(PW)"'."
8330 RETURN
8490 RETURN
8500 REM  PROZESS/GEFAENGNIS
8510 POKEVC+34,4:PRINT"   *  -   *"
8515 PRINT""
8520 PRINT"POLIZEI: SIE SIND VERHAFTET.SIE HABEN   DAS RECHT DIE EINGABE ZU VERW";
8525 PRINT"EIGERN.    ALLES, ALLES WAS SIE EINGEBEN, KANN IM  PROZESS GEGEN SIE V";
8530 PRINT"ERWENDET WERDEN."
8540 PRINT:PRINT"*          *             
8541 PRINT"* *      * *            
8550 PRINT
8560 PRINT:PRINT"RICHTER: IHNEN WIRD VORGEWORFEN EINEN
8580 IFCH=1THENPRINT"ROBOTER ANGEGRIFFEN ZU HABEN.
8590 IFCH<>1THENPRINT"DIEBSTAHL VON ESSENSWAREN GETAETIGT ZU  HABEN.
8600 PRINT"AUF WAS PLEDIEREN SIE?"
8605 PRINT
8610 INPUT"ANGEKLAGTER:";I$
8615 PRINT:IFLEFT$(I$,8)="SCHULDIG"THEN8900
8620 FORR=1TOLEN(I$)
8621 IFMID$(I$,R,1)="S"THENIFMID$(I$,R,8)="SCHULDIG"THEN8623
8622 NEXTR:GOTO8630
8623 IFR-2<0THEN8622:IFMID$(I$,R-2,10)="UNSCHULDIG"THEN8622
8624 IFMID$(I$,R-2,10)="UNSCHULDIG"THEN8622
8625 GOTO8900
8630 PRINT"RICHTER: DER STAATSANWALT WIRD NUN SEINEBEWEISE VORLEGEN."
8635 PRINT
8640 PRINT"*      *";
8645 PRINT
8650 PRINT"STAATSW.: ICH FORDERE DEN ";
8660 IFR%(L)=1THENPRINT"ANGESTELLTEN"
8665 IFR%(L)<>1THENPRINT"WACH-"
8670 PRINT"ROBOTER, SERIENNUMMER #"INT(RND(1)*999999)"AUF,ZU":PRINT"BERICHTEN."
8672 PRINT
8677 IFCH<>1THEN8700
8680 PRINT"ROBOTER: DIESER MENSCH GRIFF MICH MIT   EINE";
8681 IFIL%(9)=0THENPRINT"R STRAHLENWAFFE ";
8685 IFIL%(9)<>0THENPRINT"M FLEISCHERMESSER ";
8687 PRINT"VOR NUR":PRINT""INT(RND(1)*59)"MINUTEN,"RND(1)*59;
8688 PRINT"SEKUNDEN, AN.":PRINT
8695 PRINT"STAATSW.: ICH BEENDE DIE BEWEISAUFNAHME."
8697 GOTO8800
8700 REM  DIEBSTAHL VON ESSENSWAREN
8710 PRINT"ROBOTER: DIESER MENSCH NAHM EINE MAHL-  ZEIT IN DEM RESTAURANT EIN,";
8711 PRINT"  DAS MICH   BESCHAEFTIGT UND BEZAHLTE SEINE RECHNUNGNICHT."
8720 PRINT"STAATSW.: WANN WAR DAS?"
8730 PRINT"ROBOTER: GERADE VOR"INT(RND(1)*59)"MINUTEN,":PRINT""RND(1)*59"SEKUNDEN."
8735 PRINT
8740 PRINT"STAATSW.: HIERMIT SCHLIESE ICH DIE BE-  WEISAUFNAHME."
8745 PRINT
8800 REM  DEINE VERTEIDIGUNG
8801 PRINT"DRUECKE EINE TASTE."
8802 GETI$:IFI$=""THEN8802
8810 PRINT:PRINT"RICHTER: WAS HAT DER ANGEKAGTE NOCH DA- ZU ZU SAGEN?"
8815 PRINT
8820 INPUT"ANGEKLAGTER:";I$:IFI$=CHR$(13)THENPRINT:PRINT"RICHTER:  !":GOTO8820
8822 PRINT
8825 PRINT"RICHTER: DIE GESCHWORENEN WERDEN NUN    UEBER DEN URTEILSSPRUCH BERATEN."
8826 FORA=1TO2000:NEXT
8827 PRINT
8830 PRINT"GESCHWORENER: DAS WORT EINES ROBOTER ISTGLAUBWUERDIGER ALS DAS EINES ";
8831 PRINT"MENSCH-    LICHEN WESENS. DESHALB BEFINDE ICH DEN  ANGEKLAGTEN NACH DER ";
8832 PRINT"ANKLAGE FUER       SCHULDIG.
8840 PRINT
8900 REM  URTEIL
8905 SE=2:PRINT"RICHTER: SIE SIND HIERMIT ZU";
8910 IFCH<>1THEN8920
8911 PRINT"M  AUF  DEM   VERURTEILT."
8912 PRINT:PRINT:PRINT"DU HAST .":PRINT"ENDE NACH"T" VERSUCHEN.":END
8920 PRINT" "SE"JAHREN  ZUCHTHAUS VRURTEILT.":PRINT"GERICHTSDIENER, BITTE!
8921 PRINT"SCHAFFEN SIE DEN GEFANGENEN WEG...      NAECHSTER FALL!"
8930 PRINT:L=28
8940 FORA=1TONI:IFIL%(A)=0THENIL%(A)=29
8942 M=-ABS(M)
8945 NEXTA
8950 XX=1:RETURN
9000 REM  SCHUSS
9010 IFIL%(9)<>0THENPRINT"MIT WAS DENN?":RETURN
9020 IFR%(L)=0THENPRINT"NICHTS ZUM DRAUFSCHIESEN DA.":RETURN
9030 IFR%(L)<>3THENPRINT"DER SCHUTZSCHILD DES ROBOTER HAELT DIE  STRAHLEN ZURUECK."
9031 IFR%(L)<>3THENCH=1:GOTO8500
9040 PRINT"DER DEFEKT, DER DEN ROBOTER ZUR FEHL-   FUNKTION BRACHTE, BEEINTRAECH";
9041 PRINT"TIGTE AUCH SEINEN NORMALEN UNVERWUNDBAREN SCHUTZ-  SCHILD."
9042 PRINT"DEIN SCHUSS HAT DEN ROBOTER ZERSTOERT."
9060 R%(L)=0
9070 RETURN
9500 REM  KAUFEN
9501 IFFW%(1)<1ORFW%(1)>NITHENPRINT"GIBT'S HIER NICHT.":RETURN
9503 IFIL%(FW%(1))=0THENPRINT"DU SCHLEPPST ES SCHON MIT DIR 'RUN.":RETURN
9505 IFIL%(FW%(1))<>LTHENPRINT"GIBT'S HIER NICHT.":RETURN
9510 IFPR(FW%(1))=0THENPRINT"DA IST KEIN PREISSCHILD DRAUF.":RETURN
9520 P=PR(FW%(1))
9530 IFP>MTHENPRINT"DU HAST NICHT GENUG GELD!":RETURN
9540 M=M-P
9550 PR(FW%(1))=0
9560 GOTO3000
10000 REM  COMPUTER
10002 IFIL%(4)<>LTHENPRINT"NICHTS ZUM EINSCHALTEN DA.":RETURN
10005 PRINT"ROBOTER: WENN SIE FERTIG SIND DANN TIP- PEN SIE 'OFF' EIN, UM IHN AUS";
10006 PRINT"ZUSCHALTEN."
10007 INPUT"DRUECKE NUN RETURN UM DEN COMMODORE     ANZUSCHALTEN.";I$
10010 PRINT"     **** COMMODORE BASIC V.9 ****":PRINT
10020 PRINTTAB(6)2^26"KILO BYTES SYSTEM":PRINT:PRINTTAB(6)2^25"BASIC BYTES FREE"
10030 PRINT:INPUT">";I$
10040 IFI$="OPEN1-12-1"THEN10100
10041 IFI$="O1-12-1"THEN10100
10045 IFI$="OFF"THENXX=1:RETURN
10046 IFI$="?"ORI$="PRINT"THENPRINT"":GOTO10030
10047 IFLEFT$(I$,1)="?"ANDLEN(I$)>2THENPRINTMID$(I$,3,LEN(I$)-3):GOTO10030
10048 IFLEFT$(I$,5)="PRINT"ANDLEN(I$)>6THENPRINTMID$(I$+" ",7,LEN(I$)-7):GOTO10030
10050 I=INT(RND(1)*5)+1:PRINT"?";
10055 ONIGOSUB10060,10065,10070,10075,10080:PRINT"READY.":GOTO10030
10060 PRINT"SYNTAX ERROR":RETURN
10065 PRINT"INPROPER DELIMITER ERROR":RETURN
10070 PRINT"UNBALANCED COORDINATE ERROR":RETURN
10075 PRINT"UNFORMATTED REFERENCE ERROR":RETURN
10080 PRINT"UNINDEXABLE ADRESS ERROR":RETURN
10100 REM  NETWORK DATEI
10110 PRINT:PRINT"SIE SIND NUN IM DATEIEN-MODUS"
10120 PRINT:INPUT"]";I$
10125 IFI$="OFF"THENXX=1:RETURN
10130 IFI$<>"GOVT"THENPRINT"IMPROPPER DATA BANK REFERENCE":GOTO10120
10140 INPUT"FILE NAME: ";I$
10150 IFI$="POP"THENPRINT"GEGENWAERTIGE BEVOELKERUNG DER U.S A.   NACH BERICHTEN ";
10151 IFI$="POP"THENPRINT"DES CITICEN BUREAU       VOM 7/9/2121:"
10152 IFI$="POP"THENPRINT"EXAKT 0 PERSONEN":PRINT"23.241.203 ROBOTER":GOTO10120
10160 IFI$="CHRONOS"THEN10200
10170 PRINT"NO SUCH FILE":GOTO10120
10200 REM  CHRONOS
10210 INPUT"PASSWORD: ";I$
10220 IFI$<>PW$(PW)THENPRINT"IMPROPER PASSWORD":GOTO10120
10230 PRINT"DIE KOMBINATION IST :"CM%
10240 GOTO10120
11000 REM  RESTAURANT
11010 PRINT"ROBOTER: HIER IST DIE KARTE:"
11020 PRINT"    (1) MARSBURGER
11025 PRINT"        $50
11030 PRINT"    (2) 'GRUENER BAUER' (SPEZIALITAET)
11035 PRINT"        $140
11040 PRINT"    (3) KAVIAR UND CHAMPAGNER
11045 PRINT"        $350
11047 PRINT"(DRUECKE RETURN WENN DU NICHT BESTELLEN MOECHTEST.)
11050 PRINT:I$="":INPUT"IHRE BESTELLUNG: ";I$
11060 IFI$=""THENRETURN
11070 IFVAL(I$)<1ORVAL(I$)>3THEN11050
11080 PRINT"ES WIRD AUFGETRAGEN.":FORRR=1TO1000:NEXT
11090 PRINT:PRINT"MMM. ES SCHMECKT GUUUT.":FORRR=1TO1000:NEXT
11100 PRINT:PRINT"ROBOTER: MEIN HERR, IHRE RECHNUNG."
11101 IFM<50THEN11120
11102 IFVAL(I$)=1THENFORRR=1TO1000:NEXT:PRINT"ROBOTER: DANKE, MEIN HERR."
11103 IFVAL(I$)=1THENM=M-50:RETURN
11120 PRINT:PRINT"DU HAST NICHT GENUG GELD!":FORT=1TO1000:NEXT:PRINT
11130 CH=0:GOTO8500
12000 REM  UNTERGRUNDBAHN
12005 L=LV%(L,6)
12010 PRINT"DU BETRITST DIE U-BAHN AN DER":PRINTLD$(L,1)" STATION."
12015 PRINT
12020 IFLV%(L,1)<>0ANDLV%(L,2)<>0THENPRINT"WELCHER ZUG: NACH NORDEN ODER SUEDEN?
12021 IFLV%(L,1)<>0ANDLV%(L,2)<>0THENINPUTI$:I=2:IFLEFT$(I$,1)="N"THENI=1
12030 IFLV%(L,1)=0THENI=2
12040 IFLV%(L,2)=0THENI=1
12050 L=LV%(L,I)
12060 PRINT"NAECHSTE STATION: "LD$(L,1)
12065 IFLV%(L,I)=0THENPRINT"ENDSTATION.":L=LV%(L,8):XX=1:RETURN
12070 PRINT
12080 INPUT"MOECHTEST DU AUSSTEIGEN? ";I$:IFLEFT$(I$,1)="J"THENL=LV%(L,8)
12081 IFLEFT$(I$,1)="J"THENXX=1:RETURN
12090 PRINT:GOTO12050
13000 REM  ROBOTER ANREDEN
13002 IFR%(L)=0THENPRINT"NIEMAND ZUM ANSPRECHEN DA.":RETURN
13003 IFR%(L)<>1THEN13200
13010 IFL=6THEN11000
13020 IFL=34THEN13300
13030 IFL=36THEN13400
13040 IFL=3THENPRINT"ROBOTER: MOECHTEN SIE DEN COMMODORE 640 AUSPROBIEREN?":INPUTI$
13041 IFL=3THENIFLEFT$(I$,1)="J"THEN10000
13045 IFL=3THENRETURN
13050 PRINT"ROBOTER: KANN ICH IHNEN HELFEN?"
13060 INPUTI$
13065 IFI$=""THEN13060
13070 GOSUB520
13080 IFFW%(0)=10THENGOSUB9500
13085 IFFW%(1)=4ANDL=3THEN10000
13090 PRINT"ROBOTER: ICH BIN NICHT PROGRAMMIERT FRA-GEN DIESES TYPS ZU BEANTWORTEN."
13190 RETURN
13200 REM  WACH- UND BESCHEUERTE ROBIS
13210 IFR%(L)=3THENPRINT"DER ROBOTER BRINGT DICH UM, WAEHREND    DU VERSUCHST MIT ";
13211 IFR%(L)=3THENPRINT"IHM ZU KOMMUNIZIEREN.":PRINT:PRINT"STOP NACH"T"BEWEGUNGEN.":END
13220 PRINT"ROBOTER: JA?"
13230 INPUTI$
13240 IFI$<>""THENPRINT"ROBOTER: ERZAEHLEN SIE DAS DEM RICHTER."
13250 RETURN
13300 REM  UNIVERSITAET
13310 PRINT"ROBOTER: WELCHE RAUMNUMMER BENOETIGEN   SIE?":INPUTI$
13320 IFVAL(I$)<>RMTHENPRINT"ROBOTER: TUT MIR LEID, ABER DIESER RAUM IST NICHT OFFEN."
13321 IFVAL(I$)<>RMTHENRETURN
13330 PRINT:PRINT"EINE WAND TUT SICH AUF, UND DU FAEHRST  AUF EINER PLATTFORM ";
13331 PRINT"DURCH VERSCHIEDENE  KORRIDORE.":PRINT"DANN HAELT DAS GEFAEHRT AN."
13340 L=36:XX=1:RETURN
13400 REM  HALLE
13410 PRINT"ROBOTER: WOLLEN SIE IN DIE VORHALLE     ZURUECK?":INPUTI$
13411 IFLEFT$(I$,1)="J"THENL=34:XX=1:RETURN
13420 RETURN
13500 REM  VIDEOSPIEL
13510 PRINT:PRINT"KOSTEN: $2.50"
13520 IFM<2.5THENPRINT"DU KANNST ES NICHT BEZAHLEN.":RETURN
13525 :
13530 M=M-2.5
13540 GOSUB50000
13810 XX=0:GOSUB1000:RETURN
14000 REM  ZEITMASCHINE
14010 PRINT"DU BIST NUN IN DER ZEITMASCHINE!"
14020 PRINT"SETZE DIE KONTROLLEN."
14030 INPUT"JAHR";Y
14040 INPUT"MONAT";I$:INPUT"TAG";I$:INPUT"STUNDE";I$:INPUT"MINUTE";I$
14045 INPUT"SEKUNDE";I$
14050 PRINT"DIE ZEITMASCHINE BRUMMT..."
14060 FORA=1TO1000:NEXTA
14070 PRINT"DU BIST DA!"
14080 IFY>=1970ANDY<2000THENPRINT"ZUM SCHLUSS DOCH NOCH INS 20.JAHRHUNDERTZURUECK";
14081 IFY>=1970ANDY<2000THENPRINT"GEKEHRT.":PRINT"DU HAST GEWONNEN.";
14085 :
14090 IFY>2000THENPRINT"WAS SOLL DEN DAS??":PRINT"WARUM WIEDER IN DIE ZUKUNFT??"
14100 IFY<1970ANDY>=1900THENPRINT"NA, BISSCHEN FRUEH, WAS? DA WIRST DU    NOCH";
14101 IFY<1970ANDY>=1900THENPRINT1970-Y"JAHRE WARTEN MUESSEN, BIS ES ";
14102 IFY<1970ANDY>=1900THENPRINT"   COMMODORE COMPUTER GIBT."
14110 IFY<1900THENPRINT"ANGEKOMMEN IM JAHRE"Y".":PRINT"WARUM IN DIE VERGANGEN";
14111 IFY<1900THENPRINT"HEIT GEFLOGEN?"
14115 IFY<1900ORY>2000THENPRINT"FUER DAS JAHR HABE ICH KEIN ";
14116 IFY<1900ORY>2000THENPRINT"ADVENTURE-  SPIEL GESCHRIEBEN.":PRINT"DU BIST ";
14117 IFY<1900ORY>2000THENPRINT"NUN AUF DICH  ALLEIN GESTELLT,"
14118 IFY<1900ORY>2000THENPRINT"DA DIE ZEITMASCHINE KEINEN TREIBSTOFF"
14119 IFY<1900ORY>2000THENPRINT"MEHR HAT."
14120 PRINT:PRINT"ENDE NACH"T"VERSUCHEN.":GOTO40000
14500 REM  ESSEN
14502 IFFW%(1)=0ANDL=6THEN11000
14510 IFFW%(1)<1ORFW%(1)>NITHENPRINT"WAS ESSEN?":RETURN
14520 IFIL%(FW%(1))<>0THENPRINT"WAS ESSEN?":RETURN
14530 IFIW(FW%(1))>2THENPRINT"MACH DICH NICHT LAECHERLICH.":RETURN
14540 IFFW%(1)=3THENPRINT"MMM. DAS WAR GUT.":E=T:GOTO14565
14542 :
14545 A$=" MAMPF...SCHMURKS...SCHMATZ....":FORI=1TOLEN(A$):PRINTMID$(A$,I,1);
14546 FORR=1TO250:NEXT:NEXT
14550 PRINT"DU HAETTEST NIOCH EIN BISSCHEN SALZ NEH-MEN KOENNEN."
14560 IFT-E>150THENPRINT"NICHT GERADE SEHR NAHRHAFT."
14561 IFT-E>150THENPRINT"ICH BIN NOCH HUNGRIG!"
14565 IL%(FW%(1))=-1
14567 IFFW%(1)=10THENM=0
14570 RETURN
15000 REM  BRICH AUS GEFAENGNIS
15010 IFL<>28THENPRINT"WAS?":RETURN
15020 PRINT"DIE ROSTIGEN, ALTEN STANGEN BRECHEN RAUSUND GEBEN DEN WEG NACH ";
15021 PRINT"DRAUSSEN FREI."
15030 LV%(28,8)=27:J=1
15040 RETURN
15500 REM  ANGRIFF ROBOTER
15510 IFIL%(9)=0THEN9000
15515 IFR%(L)=0THENPRINT"NICHTS ZUN ANGREIFEN DA.":RETURN
15520 IFIL%(1)<>0THENPRINT"DU HAST KEINE CHANGE EINEN KAMPF GEGEN  EINEN ";
15521 IFIL%(1)<>0THENPRINT"HARTEN METALLROBOTER MIT BLOSSEN  HAENDEN ZU GEWINNEN";
15522 IFIL%(1)<>0THENRETURN
15530 PRINT"DAS MESSER KNALLT GEGEN DIE HARTE SEITE DES ROBOTERS."
15535 IL%(1)=-1
15537 IL%(14)=L
15538 IFR%(L)=3THENPRINT"DER ROBOTER BRINGT DICH UM."
15539 IFR%(L)=3THENPRINT"AUS NACH"T"VERSUCHEN.":GOTO40000
15540 CH=1:GOTO8500
16000 REM  OPEN
16010 PRINT"ALLE TUEREN OEFFNEN UND SCHLIESSEN AUTO-MATISCH. DAHER IST ES ";
16011 PRINT"NICHT NOETIG SIE  ZU OEFFNEN ODER ZU SCHLIESSEN.
16020 RETURN
16500 REM  HILF
16510 PRINT"":PRINT:POKEVC+34,7
16520 PRINT"EINIGE NUETZLICHE BEFEHLE:":PRINT:PRINT"(ENTAR)"
16530 PRINT" (OBJEKT)":PRINT" (OBJEKT)":PRINT" (OBJEKT) [ETWAS WEGWERFEN]
16540 PRINT" (OBJEKT)":PRINT" [SPRICH ROBOTER AN]"
16541 PRINT"Ơ":PRINT"[ER]Ӡ":PRINT" [UMSCHAUEN]"
16542 PRINT"TEILE IN [ ]  MIT EINTIPPEN."
16550 PRINT:RETURN
17990 RETURN
18000 REM  TITEL
18010 PRINT"";
18030 PRINT"     **** PLANET OF THE ROBOTS ****"
18031 PRINT"                ROBOT WAR
18040 PRINT:PRINT"     VON DANIEL TOBIAS     NOV.1981
18060 PRINT
18070 PRINT:PRINT:PRINT:INPUT"           ANLEITUNG? (J/N) ";I$
18071 IFLEFT$(I$,1)="N"THENPRINT"":PRINT:RETURN
18500 REM  ANLEITUNG
18510 PRINT"":PRINT:POKEVC+34,8
18520 PRINT"DURCH EINEN ZEITSPRUNG WURDEST DU       POETZLICH IN DIE ZUKUNFT BE";
18523 PRINT"FOERDERT.":PRINT
18525 PRINT"EIN KRIEG MIT NEUTRONENBOMBEN UND BAK-  TERIOLOGISCHEN";
18527 PRINT" WAFFEN ";
18530 PRINT"HAT DIE MENSCHEN  AUSGEROTTET.":PRINT:PRINT"ABER DIE COMPUTER UND ROBOTER HA";
18535 PRINT"BEN DAS NICHT GEMERKT UND TUN SO, ALS OB NICHTS GESCHEHEN WAERE."
18585 PRINT:PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18590 PRINT:PRINT:PRINT"UM DIE WELT ZU ERKUNDEN, IN DER DU GE-"
18600 PRINT"LANDET BIST, TIPPE EINFACHE SAETZE EIN"
18605 PRINT"WIE:":PRINT"'Ơ' ODER":PRINT"'Š'."
18620 PRINT:PRINT"WENN EIN ROBOTER IM RAUM IST, KANNST DU"
18625 PRINT"VERSUCHEN MIT IHM ZU REDEN, INDEM DU"
18630 PRINT"' '":PRINT"EINTIPPST,      ABER POSITIVE"
18635 PRINT"ANTWORTEN SIND NICHT IMMER GARANTIERT."
18636 PRINT:PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18640 PRINT:PRINT"'Ƞ'":PRINT"KANN MIT":PRINT"''":PRINT"ABGEKUERZT WERDEN.
18645 PRINT"DASSELBE GILT AUCH FUER ALLE ANDEREN"
18650 PRINT"HIMMELSRICHTUNGEN.":PRINT:PRINT
18655 PRINT"DAS ZIEL DES SPIELES IST, INS"
18660 PRINT"20. JAHRHUNDERT ZURUECKZUKEHREN.":PRINT"VIEL SPASS!"
18670 PRINT" GANZ NUETZLICHE BEFEHLE SIND:":PRINT
18671 PRINT" - BEENDET SPIEL (FUER IMMER)
18673 PRINT" - SAVET SPIEL AUF DISK ODER CASS.
18675 PRINT" - ZEIGT EINE  DER MOEG-     LICHEN BEFEHLE."
18800 PRINT:INPUT"*** DRUECKE RETURN ***";I$:PRINT""
18810 PRINT:PRINT"WENN DU MIT EINIGEN 'SAETZEN'            HAST, DANN"
18820 PRINT"VERSUCHE ES MIT  DEUTSCHEN -"
18830 PRINT".":PRINT
18870 PRINT:PRINT:PRINT:PRINT"VIEL SPASS !":PRINT:PRINT
18890 INPUT"**** DRUECKE RETURN ZUM BEGINNEN ***";I$:PRINT"":PRINT:RETURN
18990 RETURN
19000 REM INITIALISION
19001 PRINT"WARTE BITTE. INITIALISIERE DATA."
19002 PRINT"WENN DU KEIN 12-MINUTEN-EI HABEN MOECH- TEST, DANN SCHALTE ";
19003 PRINT"LIEBER DEN HERD AUS."
19004 FORR=0TO62:READD:POKE832+R,D:NEXT
19005 FORA=1TO8:READDN$(A):NEXTA
19020 A=1
19025 FORB=0TO1:READLD$(A,B):NEXTB:IFLD$(A,0)<>""THENA=A+1:GOTO19025
19027 NL=A-1
19030 FORA=1TONL:FORB=1TO8:READLV%(A,B):NEXTB:READR%(A):NEXTA
19040 FORA=1TONL:L%(A)=0:NEXTA
19050 A=1
19060 READID$(A),IL%(A),IW(A),PR(A):IFIL%(A)<>-999THENA=A+1:GOTO19060
19065 NI=A-1
19067 FORA=1TO10:READPW$(A):NEXTA
19070 A=1
19071 LD$(35,0)=LD$(35,0)+"TEIL ZER-   STOERT HAT. UBERALL IST SCHUTT. DIE EBE-"
19072 LD$(35,0)=LD$(35,0)+"NE VERLIERT SICH IM NEBEL."
19075 READWD$(A),W%(A,0),W%(A,1):IFWD$(A)<>""THENA=A+1:GOTO19075
19077 LD$(34,0)=LD$(34,0)+"EN ODER AEHNLICHES AM EINGANG ZUR U-BAHN ZU SE- HEN."
19078 LD$(33,0)=LD$(33,0)+" BLOCKIERT IST."
19079 LD$(27,0)=LD$(27,0)+" UND IM NORDEN IST EINE KLEINE KAMMER."
19080 NW=A-1
19082 LD$(15,0)=LD$(15,0)+" DIE      STRASSE GEHT IM SUEDEN WEITER."
19083 LD$(16,0)=LD$(16,0)+"CHER IST   AUSEINANDERGEBROCHEN UND DIE MUENZEN    L"
19084 LD$(16,0)=LD$(16,0)+"IEGEN HERUM."
19085 L=1:T=1
19087 W=0:M=-119
19088 E=0:J=0:R=0
19089 FORRR=40960TO49151:POKERR,PEEK(RR):NEXT:POKE43846,157: REM DATA KONTROLLE
19090 POKE1,54:PRINT"":PRINT:INPUT"SPIEL LADEN? (J/N) ";I$
19092 DUMMY=RND(-TI) : REM RANDOM START
19093 PW=INT(RND(1)*10)+1
19096 CM%=INT(RND(1)*9999)
19097 RM=INT(RND(1)*900)+100
19100 IFLEFT$(I$,1)="J"THENGOSUB6500
19120 RETURN
19500 REM  SPRITE DATA
19510 DATA1,128,0,1,128,0,1,128,0,1,128,0,15,252,0,15,240,0,15,252,0,15,192,0,15
19520 DATA252,0,1,32,0,7,48,0,12,24,28,24,255,224,48,6,28,96,3,0,96,3,0,96,3,0
19530 DATA96,3,0,255,255,128,37,41,0,24,198,0
20000 REM  DATA
20001 REM
20002 REM
20005 DATA"ORD ","UED ","ST ","EST ","OCH ","UNTER ","N ","AUS "
20010 REM  #PLAETZE
20030 REM  PLATZ-BESCHR.-KURZ-BESCHR.
20040 DATADU BIST AUF DEM PARKPLATZ EINES EIN-    KAUFSZENTRUMS.
20041 DATADU BIST BEI DEN PARKPLAETZEN DES EIN-   KAUFSZENTRUMS.
20050 DATADU BIST IM EINKAUFSZENTRUM. NEBEN DIR   IST EIN COMPUTER-FACHGESCHAEFT.
20051 DATADU BIST IM EINKAUFSZENTRUM NEBEN DEM    COMPUTERLADEN.
20060 DATADU BIST IM COMPUTERGESCHAEFT.
20061 DATADU BIST IM COMPUTERLADEN.
20070 DATA"IM WESTEN IST EIN GUTES COMICBUCH GE-   SCHAEFT,IM OSTEN EIN RESTAURANT.
20071 DATADU BIST BEIM COMIC-LADEN UND RESTAURANT.
20080 DATA"ES IST EIN COMIC-BUCHLADEN, DER JEDEM   SAMMLER VON COMICS SCHMEICHELT."
20081 DATADU BIST IM COMIC-BUCHLADEN.
20085 REM  6:
20090 DATADU BIST IN EINEM RESTAURANT.
20091 DATADU BIST IM RESTAURANT.
20100 DATA"IM WESTEN IST EINE ARKADE, UND IM OSTEN EIN LEBENSMITTELLADEN."
20101 DATADU BIST BEI DER ARKADE UND DEM KAUFMANN.
20110 DATADU BIST IN DEM BOGENGANG.
20111 DATADU BIST IN DER ARKADE.
20120 DATAIM WESTEN IST EINE FLEISCHEREI UND IM   OSTEN EIN BEKLEIDUNGSGESCHAEFT.
20121 DATADU BIST ZWISCHEN DER FLEISCHEREI UND DEMBEKLEIDUNGSGESCHAEFT.
20130 DATADU BIST IN EINER FLEISCHEREI.
20131 DATADU BIST IN DER FLEISCHEREI.
20140 DATADU BIST IN EINEM BEKLEIDUNGSGESCHAEFT.
20141 DATADU BIST IN DEM BEKLEIDUNGSGESCHAEFT.
20150 DATADU BIST IN EINEM LEBENSMITTELGESCHAEFT.
20151 DATADU BIST IM LEBENSMITTELLADEN.
20160 DATADU BIST AUF EINER N-S STRASSE. EIN EIN- KAUFSZENTRUM IST IM WESTEN.
20161 DATADU BIST AUF DER STRASSE BEIM EINKAUFS-  ZENTRUM.
20170 DATANACH 100 METERN IST DIE STRASSE DURCH   HERABGEFALLENE STEINE BLOCKIERT.
20171 DATADU BIST AM ENDE DER STRASSE.
20180 DATA"DU BIST AN EINEN INFORMATIONSSTAND, DER VON EINEM ROBOTER BESETZT IST."
20181 DATADU BIST BEIM INFO-STAND.
20190 DATA"DU BIST IN EINER TELEFONZELLE. DAS TELE-FON IST KAPUTT, DER MUENZSPEI"
20191 DATADU BIST IN DER TELEFONZELLE.
20200 DATAI,I
20210 DATADU BIST IN EINER BUECHEREI.
20211 DATADU BIST IN DER BUECHEREI.
20220 DATAIM WESTEN IST EINE BUECHEREI UND IM OST-EN DIE STADTHALLE.
20221 DATADU BIST BEI DER BUECHEREI UND DER STADT-HALLE.
20230 DATADU BIST IM FOYER DER STADTHALLE. ES GIBTHIER EINE TREPPE.
20231 DATADU BIST IM FOYER DER STADTHALLE.
20240 DATADIE STRASSE ENDET HIER. EINE TREPPE     FUEHRT ZU EINER U-BAHN STATION.
20241 DATADU BIST BEI DER U-BAHN STATION.
20245 DATAS,STADTHALLE
20250 DATA"DU BIST IN EINEM KORRIDOR, DER ZU BUEROSIM OSTEN FUEHRT.
20251 DATADU BIST IM KORRIDOR.
20260 DATAES GIBT HIER EIN BUERO IM NORDEN UND    EINS IN SUEDEN.
20261 DATADU BIST ZWISCHEN ZWEI BUEROS.
20270 DATADU BIST IN EINEM BUERO.
20271 DATADU BIST IM BUERO.
20280 DATADU BIST IN EINEM BUERO.
20281 DATADU BIST IM BUERO.
20290 DATADU BIST IN EINEM KORRIDOR DES GEFAENG-  NISSES. EINE ZELLE IST IM SUEDEN
20291 DATADU BIST IM GEFAENGNISKORRIDOR.
20300 DATADU BIST IN EINER GEFAENGNISZELLE.
20301 DATADU BIST IN DER ZELLE
20310 DATADU BIST IN EINER KLEINEN KAMMER.
20311 DATADU BIST IN DER KAMMER.
20320 DATAS,MARKTSTRASSE
20330 DATAS,METRO UNIVERSITAET
20340 DATAS,ENDSVILLE
20350 DATA"DU BIST AUF EINER STRASSE, DIE IN BEIDENRICHTUNGEN DURCH TRUEMMER"
20351 DATADU BIST AUF EINER BLOKIERTEN STRASSE.
20360 DATADU BIST IN DER HAUPTHALLE DER METRO     UNIVERSITAET. ES SIND KEINE TUER
20361 DATADU BIST IM FOYER DER UNI.
20370 DATA"DU BIST IN EINER EBENE, WO EINE BOMBEN- EXPLOSION EINEN GANZEN STADT"
20371 DATADU BIST BEI DER UNTERGRUNDBAHN-STATION.
20380 DATADU STEHST VOR EINER TUER
20381 DATADU STEHST VOR EINER TUER
20390 DATA"DU BIS IN LABOR VON PROJEKT . SIEARBEITEN AN ZEITVERSCHIEBUNG."
20391 DATADU BIST IM LABORATORIUM.
20400 DATAT,T
20405 DATADU BIST AUF DER EBENE.
20406 DATADU BIST AUF DER EBENE.
20410 DATADU BIST BEI EINER TELEFONZELLE.
20411 DATADU BIST BEI EINER TELEFONZELLE.
20990 DATA"",""
21000 REM  BEWEGUNGEN, ROBOTER
21010 DATA0,0,13,0,0,0,2,0,0
21020 DATA7,4,0,0,0,0,3,1,0
21030 DATA0,0,0,0,0,0,0,2,1
21040 DATA2,0,6,5,0,0,0,0,0
21050 DATA0,0,0,0,0,0,0,4,1
21055 REM  6:
21060 DATA0,0,0,0,0,0,0,4,1
21070 DATA9,2,12,8,0,0,0,0,0
21080 DATA0,0,0,0,0,0,0,7,0
21090 DATA0,7,11,10,0,0,0,0,0
21100 DATA0,0,0,0,0,0,0,9,0
21110 DATA0,0,0,0,0,0,0,9,1
21120 DATA0,0,0,0,0,0,0,7,1
21130 DATA14,15,0,1,0,0,0,0,0
21140 DATA0,13,0,0,0,0,0,0,0
21150 DATA13,19,0,0,0,0,17,0,0
21160 DATA0,0,0,0,0,0,0,40,0
21170 DATA0,0,0,0,0,0,0,15,1
21180 DATA0,0,0,0,0,0,0,19,0
21190 DATA15,21,20,18,0,0,0,0,0
21200 DATA0,0,0,0,23,27,0,19,26
21210 DATA19,0,0,0,0,22,0,0,3
21220 DATA0,30,0,0,0,0,0,21,0
21225 DATA0,0,24,0,0,20,0,0,23
21230 DATA26,25,0,23,0,0,0,0,0
21240 DATA0,0,0,0,0,0,0,24,3
21245 DATA0,0,0,0,0,0,0,24,0
21250 DATA29,28,0,0,20,0,0,0,25
21260 DATA0,0,0,0,0,0,0,0,0
21270 DATA0,0,0,0,0,0,0,27,0
21280 DATA22,31,0,0,0,0,0,33,0
21290 DATA30,32,0,0,0,0,0,34,0
21300 DATA31,0,0,0,0,0,0,35,0
21310 DATA0,0,0,0,0,30,0,0,0
21320 DATA0,0,0,0,0,31,0,0,1
21330 DATA39,39,39,39,0,32,0,0,0
21340 DATA0,0,0,0,0,0,37,0,1
21350 DATA0,0,0,0,0,0,38,36,0
21360 DATA0,0,0,0,0,0,0,0,0
21370 DATA39,39,39,39,0,0,0,0,0
21380 DATA39,39,39,39,0,0,16,0,0
23000 REM GEGENSTAENDE
23030 DATAFLEISCHERMESSER,10,15,0
23040 DATAWAAGE,10,140,0
23050 DATANAHRUNGS PILLEN,12,1,10
23060 DATACOMMODORE 640 COMPUTER,3,40,10000
23070 DATAVIDEOSPIEL MASCHINE,8,-1,0
23080 DATAHERRENANZUG,11,6,995
23085 DATAKRAWATTE,11,.25,20
23090 DATACOMIC,5,.3,6
23100 DATALASER PISTOLE,14,3,0
23110 DATAMUENZEN,16,5,0
23120 DATABUCH,18,3,0
23130 DATAI.D. CARD,29,.01,0
23140 DATABRIEF,26,0.05,0
23150 DATAZERSTREUTE METALLSTUECKE,-1,15,0
23160 DATAZEITMASCHINE,37,2000,0
23990 DATA"",-999,-999,-999
23995 DATASESAM,SNARK,QUARK,BIRNBAUM,MONDSCHEIN,SCHUH,TRUTHAHN,WEIHNACHTEN
23996 DATATHORANIA,ROBOTWAR
24000 REM  WOERTER
24030 DATAN,1,101
24040 DATAS,1,102
24050 DATAO,1,103
24060 DATAW,1,104
24070 DATAH,1,105
24080 DATAR,1,106
24090 DATAIN,1,107
24100 DATARAUS,1,108
24110 DATANIMM,2,-1
24115 DATANEHME,2,-1
24120 DATAGEH,1,-1
24125 DATAGEHE,1,-1
24130 DATAWEG,3,-1
24140 DATALOOK,4,-1
24180 DATAINV,5,-1
24190 DATAQUIT,99,-1
24200 DATASAVE,6,-1
24220 DATAKAUF,10,-1
24225 DATAKAUFE,10,-1
24230 DATAWIEG,7,-1
24235 DATAWIEGE,7,-1
24240 DATALES,8,-1
24245 DATALESE,8,-1
24255 DATAUNT,8,-1
24256 DATAUNTERSUCHE,8,-1
24257 DATAUNTERSUCH,8,-1
24260 DATAMESSER,-1,1
24261 DATAFLEISCHERMESSER,-1,1
24270 DATAWAAGE,-1,2
24280 DATAPILLEN,-1,3
24290 DATACOMMODORE,-1,4
24300 DATACOMPUTER,-1,4
24315 DATASPRICH,11,-1
24320 DATABUCH,-1,11
24325 DATAVIDEOSPIEL,-1,5
24330 DATASPIEL,12,-1
24335 DATASPIELE,12,-1
24340 DATAANZUG,-1,6
24345 DATAHERRENANZUG,-1,6
24350 DATAKRAWATTE,-1,7
24360 DATACOMIC,-1,8
24370 DATAESS,13,-1
24375 DATAESSE,13,-1
24380 DATABRICH,14,-1
24382 DATABRECHE,14,-1
24383 DATAENTFERNE,14,-1
24384 DATABRECHE AUS,14,-1
24385 DATARENN WEG,14,-1
24386 DATABRICH AUS,14,-1
24387 DATARENNE WEG,14,-1
24390 DATAHAU,14,-1
24391 DATALAUF WEG,14,-1
24395 DATAVERSCHWINDE,14,-1
24400 DATAPISTOLE,-1,9
24406 DATALASER,-1,9
24410 DATAMUENZEN,-1,10
24420 DATAGELD,-1,10
24430 DATAKASTEN,-1,10
24435 DATASPEICHER,-1,10
24440 DATASCHIESS,9,-1
24445 DATAERSCHIESS,9,-1
24450 DATAANGRIFF,15,-1
24455 DATAGREIF,15,-1
24460 DATAI.D.,-1,12
24465 DATAIDENTITY,-1,12
24470 DATACARD,-1,12
24475 DATAKARTE,-1,12
24480 DATABRIEF,-1,13
24490 DATASTUECKE,-1,14
24495 DATAMETALL,-1,14
24500 DATAOEFFNE,16,-1
24510 DATASCHLIESSE,16,-1
24515 DATAMACHE,16,-1
24520 DATAHILF,17,-1
24530 DATAAN,18,-1
24540 DATASTANGEN,-1,200
24545 DATASTANGE,-1,200
24550 DATASTAEBE,-1,200
24555 DATASTAB,-1,200
24895 REM ***** UNABGEKUERTZT
24900 DATANORD,1,101
24910 DATASUED,1,102
24920 DATAOST,1,103
24930 DATAWEST,1,104
24940 DATAHOCH,1,105
24950 DATARUNTER,1,106
24960 DATAINVENTAR,5,-1
24980 DATAAUS,1,108
24990 REM ***** WEITERE BEFEHLE UND                     WOERTER
25240 REM **** DEUTSCH
25250 DATAWERF,3,-1
25270 DATASCHAU,4,-1
25280 DATAUMSCHAU,4,-1
25330 DATAZEIG,4,-1
25350 DATAINVENTAR,5,-1
29998 DATA"",-999,-999
29999 REM ******************************
30000 INPUTA$:IFLEFT$(A$,1)<>"J"THENRETURN
30005 PRINT"ROBOTER: WAS SOLL ICH IHNEN ZEIGEN?":INPUTA$:FORR=1TOLEN(A$)
30006 IFMID$(A$,R,1)="K"THENIFMID$(A$,R,5)="KARTE"THEN30029
30008 NEXTR
30009 FORR=1TOLEN(A$)
30010 IFMID$(A$,R,1)="P"THENIFMID$(A$,R,4)="PLAN"THEN30029
30011 NEXTR
30028 PRINT"ROBOTER: KRZZFLSCH, I..I..INFORMATIONS- STAND K..K..A..PUTT.":RETURN
30029 PRINT:PRINT"EINE WAND SCHIEBT SICH LANGSAM HOCH UND DU SIEST EINE ANGESE";
30030 PRINT"NGTE KARTE:
30035 FORR=1TO1000:NEXTR:POKEVC+17,PEEK(VC+17)-64
30040 PRINT"         
30050 PRINT"                 
30060 PRINT"          E   
30070 PRINT"             S   
30080 PRINT"               
30090 PRINT"              U      
30100 PRINT"          ݿ       
30110 PRINT"          ݿ   M֦  
30120 PRINT"          ɿ       
30130 PRINT"             U֦  
30140 PRINT"          ݿ           
30150 PRINT"          ʮ        צ֦ 
30160 PRINT"              E 
30170 PRINT"            ɿ
30180 PRINT"                 
30190 PRINT"MITNEHMEN GEHT NICHT;KARTE IST FESTGENA-GELT."
30195 INPUT"DRUECKE RETURN";I$
30200 PRINT:PRINT"DIE WAND SCHIEBT SICH WIEDER ZU."
30210 FORR=1TO10:PRINT"":FORRR=1TO200:NEXT:NEXT:PRINT""
30900 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
31000 PRINT"ZUM ANSCHAUEN DES COMICS DRUECKE 'A'    SONST NUR 'RETURN'."
31005 INPUTA$:IFA$<>"A"THENRETURN
31006 PRINT:PRINT"VIEL SPASS!":POKEVC+17,PEEK(VC+17)-64
31040 RESTORE:FORR=0TO62:READD:POKE832+R,D:NEXT
31050 VC=53248:POKE2040,13:POKEVC,0:POKEVC+1,0:POKEVC+21,1:POKEVC+23,1:POKEVC+29,1
31060 PRINT"":FORQ=1TO25:PRINT" ";:NEXT
31100 PRINT"":PRINT,"           "
31105 PRINT," SUPER-    "
31110 PRINT," ROBOT  "
31120 PRINT,"     "
31130 PRINT,"     "
31140 PRINT,"        "
31150 PRINT,"        "
31160 PRINT,"     "
31170 PRINT,"     "
31180 PRINT,"        "
31190 PRINT,"        "
31200 PRINT,"     "
31210 PRINT,"     "
31220 PRINT,"        "
31230 PRINT,"           "
31240 FORR=1TO6:FORD=1TO2:PRINTTAB(24+R)" ":NEXT:PRINT"":NEXT
31250 FORR=1TO6:FORD=1TO2:PRINTTAB(30+R)" ":NEXT:PRINT"":NEXT
31260 FORQ=36TO39:PRINTTAB(Q)" ";:NEXT:FORQ=1TO1000:NEXT
31270 POKEVC+1,136:FORQ=0TO60:POKEVC,Q:FORR=0TO10*Q-400:NEXT:FORR=1TO9:NEXT:NEXT
31290 P=PEEK(VC+33):FORQ=1TO5:POKEVC+33,2
31300 FORR=1TO70:NEXT:POKEVC+33,P:FORR=1TO70:NEXT:NEXT
31310 FORQ=15TO1STEP-1:FORR=1TO12:POKE1024+9+R+40*Q,32:NEXT:IFQ=13THEN31330
31320 NEXT:GOTO31340
31330 PRINT"B U M M !" :NEXT
31340 FORQ=1TO1000:NEXT:PRINT"         "
31350 FORQ=60TO255:POKEVC,Q:FORR=1TOQ-Q/1.25:NEXT:NEXT
31360 PRINT""TAB(21)"HUH ?";:FORQ=1TO500:NEXT:PRINT"     "
31370 FORQ=1TO30:NEXT:PRINT""TAB(21)"AAAAAAAHHH!"
31380 FORQ=136TO168:POKEVC+1,Q:FORR=1TO129-(Q-136)*4:NEXT:NEXT
31390 FORQ=62TO0STEP-1:POKE832+Q,RND(1)*256:NEXT:FORQ=0TO62:POKE832+Q,0
31400 FORR=1TO10:NEXT:NEXT
31410 POKEVC+21,0                  
31420 PRINT""TAB(21):FORQ=1TO21:PRINTMID$("           ",Q,1);
31430 FORR=1TO50:NEXT:NEXT:PRINT""
32040 DATAWAAGE,10,140,0
33900 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
40000 FORT=1TO2000:NEXT
40010 POKE1,55:POKEVC+17,PEEK(VC+17)-64
40020 END
50000 REM  VIDIOSPIEL
50010 INPUT"DRUECKE RETURN.";I$:POKEVC+17,PEEK(VC+17)-64
50800 POKE650,128:POKE53280,254:POKE53281     ,254:POKE646,0:PRINTCHR$(8)
51100 PRINT"******************************************************************";
51300 PRINT"************************   MASTER - KILLER   ********************";
51400 PRINT"*****************************             PUNKTETABELLE : "
51500 PRINT"    ձ = 100  PUNKTE      J = LINKS"
51600 PRINT"     = 500 PUNKTE       K = RECHTS"
51700 PRINT"    ֮ = IHRE STATION     S = SCHUSS"
51750 PRINT"       DIE HOEHE DES RAUMSCHIFFES"
51800 PRINT""
51950 PRINT"    1.  SPIEL   :  DRUECKE 'SPACE'"
52000 FORI=35TO0STEP-1:PRINTSPC(I)" "     :GETA$:IFA$=" "THEN53000
52100 FORR=1TO60:NEXT:NEXTI
52200 FORI=0TO35:PRINTSPC(I)" ":GETA$     :IFA$=" "THEN53000
52300 FORR=1TO60:NEXTR:NEXTI:GOTO52000
53000 PRINT"":POKE53280,0:POKE53281,0
53100 XQ=RND(1)*38:Y=0:VI=1024:FA=55296:VU=1984:FU=56256:Z=RND(1):TR=0
53120 IFZ>.9THENGOTO61400:
53130 S=S-1:Y=Y+1:POKEVI+Y-1,32:POKEVI+Y,     85:POKEVI+Y+1,113:POKEVI+Y+2,73
53135 POKEFA+Y,5:POKEFA+Y+1,5:POKEFA+Y+2,     5
53137 IFY>900THEN60000
53140 GETA$
53150 IFA$="J"THENXQ=XQ-1
53160 IFA$="K"THENXQ=XQ+1
53170 IFA$="S"ANDS<-2THENS=22
53180 IFXQ>38THENXQ=XQ-1
53190 IFXQ<1THENXQ=XQ+1
53900 POKEVU+XQ-2,32:POKEVU+XQ+2,32:POKEVU+XQ-41,32:POKEVU+XQ-39,32
54000 POKEVU+XQ-1,112:POKEVU+XQ,86:POKEVU+XQ+1,110:POKEVU+XQ-40,66
54010 POKEFU+XQ-1,10:POKEFU+XQ,10:POKEFU+XQ+1,10:POKEFU+XQ-40,13
54700 IFS=22THENU=XQ
54750 IFS=22THEN62000
54800 IFS>-2THENTR=PEEK(VI+40*S+U)
54900 IFTR=85ORTR=113ORTR=73ORTR=109ORTR=     114ORTR=125THEN56900
55000 IFS>-2THENPOKEVI+40*S+U,66:POKEVI+4     0*S+40+U,32:POKEFA+40*S+U,3
56000 GOTO53120
56900 POKE53280,7:POKE53281,7
56901 FORJ=15TO0STEP-1
56902 POKEQ,J:POKECC,15:POKEFH,90:POKEFL,200:POKEW,129
56903 NEXTJ
56904 POKEW,0:POKECC,0
57000 POKEVI+40*S+U-41,85:POKEVI+40*S+U-4     0,67
57100 POKEVI+40*S+U-39,73:POKEVI+40*S+U-1,66:POKEVI+40*S+U,224:POKEVI+40*S+U+1,66
57200 POKEVI+40*S+U+41,75:POKEVI+40*S+U+4     0,67:POKEVI+40*S+U+39,74
57400 POKEFA+40*S+U-41,7:POKEFA+40*S+U-40     ,7
57500 POKEFA+40*S+U-39,7:POKEFA+40*S+U-1,     7:POKEFA+40*S+U,7:POKEFA+40*S+U+1,7
57600 POKEFA+40*S+U+41,7:POKEFA+40*S+U+40     ,7:POKEFA+40*S+U+39,7
57700 POKE53280,0:POKE53281,0
57800 PRINT"":FORR=1TO8:NEXT
58250 IFF=66ORG=66THEN61100
58260 IFZ<.9THENSP=SP+90+INT((1000-Y)/10)
58265 IFZ>.9THENSP=SP+490+INT((100      0-Y)/10)
58300 PRINT"   SPIELER HAT NUN :"
58400 PRINT"   ";SP" PUNKTE":SZ=SZ+1:IFSZ>3THEN63000
58500 PRINT"    NAECHSTES SPIEL"
58600 PRINT"    DRUECKE 'SPACE'"
58700 GETA$:IFA$=""THEN58700
58800 IFA$=" "THEN59000
58900 GOTO58700
59000 S=-1:F=0:G=0:GOTO53000
60000 F=PEEK(VI+Y+3):G=PEEK(VI+Y+4):IFF=      66ORG=66THEN61000
60001 GOTO53140
61000 S=0:U=Y+3:GOTO6900
61100 PRINT"     SIE HABEN SICH IHR RAUMSCHIFF"
61200 PRINT"     ZERSTOEREN LASSEN !"
61250 PRINT"    DAS GIBT 1000 PUNKTE ABZUG !"
61300 SP(B)=SP(B)-1000:F=0:GOTO58300
61400 S=S-1:Y=Y+2:POKEVI+Y-2,32:POKEVI+Y      -1,32
61405 POKEVI+Y,109:POKEVI+Y+1,114:POKEVI      +Y+2,125
61410 GOTO53135
62000 SI=54272:FL=SI:FH=SI+1:TL=SI+2:TH=SI+3:W=SI+4:CC=SI+5:D=SI+6:Q=SI+24
62001 FORE=15TO0STEP-1
62002 POKEQ,E:POKECC,15:POKED,0:POKEFH,10:POKEFL,50:POKEW,129
62003 NEXTE
62004 POKEW,0:POKECC,0
62005 GOTO53120
63000 PRINT"         G A M E    O V E R "
63001 FORR=1TO2000:NEXT:PRINT""CHR$(151):POKE53248+32,12:POKE53248+33,12
63010 POKE650,0:PRINTCHR$(9)
63020 VC=53248:POKEVC+17,PEEK(VC+17)OR64:POKEVC+35,11:RETURN
READY.
